topic Location of REFLINE label in PROC SGPANEL in Graphics Programming

Location of REFLINE label in PROC SGPANEL

Richard5 — Fri, 28 Jun 2024 13:49:27 GMT

Hi,

I would like to know if it is possible to position REFLINE label outside of plot area in PROC SGPANEL. Based on SAS documentation it seems only possible in PROC SGPLOT, where labelloc option can be defined.

See following example:

/* create rudimentary dataset */
data have(drop=i);
call streaminit(123);
format Date date9.;
do i=0 to 24;
	do Country=1 to 3;
		do Category=1 to 4;
			Date=intnx('month','31dec2020'd,i,'end');
			n=rand('normal',100,5);
			output;
		end;
	end;
end;
run;

/* SGPANEL with REFLINE labels inside the plot area */
ods graphics / width=600 height=300;
proc sgpanel data=have pctlevel=group;
panelby Country / columns=3;
vbar Date / response=n group=Category stat=percent;
colaxis type=time;
refline '30jun2021'd / axis=x label='REF 1' label;
refline '31dec2021'd / axis=x label='REF 2';
run;

/* SGPLOT with REFLINE labels outside the plot area */
proc sgplot data=have(where=(country=1)) pctlevel=group;
vbar Date / response=n group=Category stat=percent;
xaxis type=time;
refline '30jun2021'd / axis=x label='REF 1' labelloc=outside;
refline '31dec2021'd / axis=x label='REF 2' labelloc=outside;
run;
ods graphics / reset;

P.S. of course, I can do loop and instead of PROC SGPANEL do multiple PROC SGPLOTs, but that is not my question.

Thanks for any help,

Richard

Re: Location of REFLINE label in PROC SGPANEL

Rick_SAS — Fri, 28 Jun 2024 13:59:14 GMT

No, it isn't possible. The documentation for the REFLINE statement in PROC SGPANEL shows that the only option for the label is the LABELPOS= option, which controls whether the label is on the left/right or bottom/top. There is not an option to put the label outside the plot area.

Think about a 3x3 panel, there isn't really an "outside" region for the middle plot. Similarly, plots along the first column don't have an "outside-right" region.

Just to be sure, I checked the doc for the REFERENCELINE statement in the GTL, which is the underlying source for the REFLINE statements in PROC SGPANEL. Although there is a CURVELABELLOCATION= option, the doc states the the option is not available for paneled plots:

Restriction	OUTSIDE cannot be used when the REFERENCELINE is used in multicell layouts such as LATTICE, DATAPANEL, or DATALATTICE, where axes might be external to the grid.

Re: Location of REFLINE label in PROC SGPANEL

Richard5 — Fri, 28 Jun 2024 14:11:44 GMT

Alright, thank you!

Re: Location of REFLINE label in PROC SGPANEL

Ksharp — Sat, 29 Jun 2024 08:38:42 GMT

You could make more OFFSET at Y axis top to display this label.

ods graphics / width=600 height=300;
proc sgpanel data=have pctlevel=group;
panelby Country / columns=3;
vbar Date / response=n group=Category stat=percent;
colaxis type=time;
rowaxis offsetmax=0.1;
refline '30jun2021'd / axis=x label='REF 1' label;
refline '31dec2021'd / axis=x label='REF 2';
run;