topic Re: control marker size on spaghetti plots in Graphics Programming

control marker size on spaghetti plots

vstorme — Mon, 06 Nov 2023 12:51:47 GMT

Dear all,

I have following code:

data myattrmap;
length linecolor $ 6 linepattern $ 5 markercolor $ 6 markersymbol $ 13;
input ID $ value $ linecolor $ linepattern $ markercolor $ markersymbol $;
datalines;
myid  young teal   solid teal    DiamondFilled
myid  old   purple solid purple  DiamondFilled
;
run;
proc print data = myattrmap;
run;

ods graphics/ reset=all width=16cm ;
title "Results &var by concentration and leaf stage";
Proc SGpanel data = &lib..rides_anno_flag noautolegend dattrmap = myattrmap;
  PanelBy treatment / columns=2;
  series x=date y=&var / group=uniqueID
                         grouplc=leaf lcattrid=myid /*lc line color*/
                         grouplp=leaf lpattrid=myid /*lc line pattern*/
                         groupmc=leaf mcattrid=myid /*lc marker color*/
                         groupms=leaf mcattrid=myid /*lc marker symbol*/
                         markerattrs=(size=10)
                         name='grouping'; 
  keylegend 'grouping' / type=linecolor;
  rowaxis display=(nolabel) grid;
  colaxis values=('11oct2023'd, '18oct2023'd, '25oct2023'd, '2nov2023'd)
          valuesformat = date7.;
  where flag = 0;
run;
title;

according to the SAS documentation, I should be able to control the marker size with markerattrs, but it does not seem to have an effect:

I am using sas-analytics-pro on SAS Studio (SAS Viya) version: V.04.00M0P031323

Can somebody clarify this?

Thanks, Veronique

Re: control marker size on spaghetti plots

sbxkoenk — Mon, 06 Nov 2023 13:03:17 GMT

Not sure these blog posts contain the answer to your specific question, but wanted to let them know to you anyway:

Create spaghetti plots in SAS
By Rick Wicklin on The DO Loop June 2, 2016
https://blogs.sas.com/content/iml/2016/06/02/create-spaghetti-plots-in-sas.html
Lasagna plots in SAS: When spaghetti plots don't suffice
By Rick Wicklin on The DO Loop June 8, 2016
https://blogs.sas.com/content/iml/2016/06/08/lasagna-plot-in-sas.html

BR, Koen

Re: control marker size on spaghetti plots

sbxkoenk — Mon, 06 Nov 2023 13:07:35 GMT

Another option ... try GTL with PROC SGRENDER.

Sample 52962: Create a spaghetti plot with the Graph Template Language (GTL)
https://support.sas.com/kb/52/962.html

Koen

Re: control marker size on spaghetti plots

sbxkoenk — Mon, 06 Nov 2023 13:12:34 GMT

OK, I found it ...
You need

markers markerattrs=(size=10);

instead of just

markerattrs=(size=10);

Koen

Re: control marker size on spaghetti plots

vstorme — Mon, 06 Nov 2023 14:11:48 GMT

ah yes, that makes sense! I had it before and then removed it when adding groupmc and groupms.

topic Re: control marker size on spaghetti plots in Graphics Programming

control marker size on spaghetti plots

Re: control marker size on spaghetti plots

Re: control marker size on spaghetti plots

Sample 52962: Create a spaghetti plot with the Graph Template Language (GTL)https://support.sas.com/kb/52/962.html

Re: control marker size on spaghetti plots

Re: control marker size on spaghetti plots

Sample 52962: Create a spaghetti plot with the Graph Template Language (GTL)
https://support.sas.com/kb/52/962.html