topic Re: How to Italicize portion of yaxis label and rest would be normal? in Graphics Programming

How to Italicize portion of yaxis label and rest would be normal?

nickpatel — Mon, 25 Sep 2023 13:45:19 GMT

data sample;
input x y;
datalines;
1 10
2 20
3 15
4 25
5 30
;
ods rtf file="\\Desktop\RC\test.rtf" bodytitle_aux image_dpi = 300 nogfootnote nogtitle;
ods escapechar = '^';
/* Create a scatter plot with a custom Y-axis label */
proc sgplot data=sample;
scatter x=x y=y / markerattrs=(symbol=circlefilled);
yaxis label="Normal(i^Italicized)" labelattrs=(size=12 );
run;
ods _all_ close;

Re: How to Italicize portion of yaxis label and rest would be normal?

ballardw — Mon, 25 Sep 2023 15:17:59 GMT

First tell exactly which part of the label is to be in italics.

It isn't really clear from your code. Generally any modifier to text appearance come before the actual text to modify. So your attempt would possibly only effect a closing ).

Re: How to Italicize portion of yaxis label and rest would be normal?

nickpatel — Mon, 25 Sep 2023 15:33:57 GMT

Hi Ballardw,

Thank you for help. In label "Normal(i^Italicized)" .. the part it says "Italicized" need to be Italicized.

Best,

Nick

Re: How to Italicize portion of yaxis label and rest would be normal?

DanH_sas — Mon, 25 Sep 2023 16:33:54 GMT

Rich-text functionality is not currently supported in axis labels. You'll need to use annotation to do it. Something like the following:

data axislabel;
retain drawspace "wallpercent" x1 -7.5 y1 50 rotate 90 textsize 12 width 50;
input function $ textstyle $ label $ 17-26;
cards;
text     normal Normal 
textcont italic Italicized
;
run;

proc sgplot data=sample sganno=axislabel pad=(left=30);
scatter x=x y=y / markerattrs=(symbol=circlefilled);
yaxis display=(nolabel);
run;

Re: How to Italicize portion of yaxis label and rest would be normal?

nickpatel — Mon, 25 Sep 2023 17:24:39 GMT

hi Dan,

Thank you so much, so using annotation dataset works...

Regards,

nick