topic Re: Title in 2 parts over a graphic with divergent X-axis in Graphics Programming

Title in 2 parts over a graphic with divergent X-axis

Karolus — Wed, 30 Aug 2023 22:52:46 GMT

Hi,

I've created the graphic in the attachment via Sgplot. However, I also need to add 2 titles at the same level over the graphic. The graphic has a divergent x-axis (of course, the left side is actually negative but formatted as positive for printing). One title should appear on the left side of the 0 base axis-line, the other title on the right side of this 0 base axis-line.

The title statement only offers left, right and center, the "left option" sends the "title ABC" way far to the left, the "center option" overlaps the "title XYZ". The title XYZ luckily locates well with the option "right".

Sugestions on how to precisely locate the 2 titles in the same line in this case? Thanks for your time.

Regards,

Karl

Re: Title in 2 parts over a graphic with divergent X-axis

Karolus — Wed, 30 Aug 2023 22:51:29 GMT

p.s. I don't see my atachment...trying again.

Re: Title in 2 parts over a graphic with divergent X-axis

DanH_sas — Wed, 30 Aug 2023 22:51:33 GMT

The graph didn't get attached.

Re: Title in 2 parts over a graphic with divergent X-axis

Karolus — Wed, 30 Aug 2023 22:52:11 GMT

yeah, I noticed, I just added it

Re: Title in 2 parts over a graphic with divergent X-axis

DanH_sas — Wed, 30 Aug 2023 23:23:18 GMT

There are a few ways to of this, but this way is probably the most straightforward. The key here is the annotation, and the PAD option on the procedure. Let me know if you have any questions.

Thanks!

Dan

data test;
input x y;
cards;
-60 0
60  100
;
run;

data anno;
retain function "text" y1 100 drawspace "wallpercent" width 40
       anchor "bottom" textstyleelement "GraphTitleText";
input x1 label $ 4-12;
cards;
25 Title ABC
75 Title XYZ
;
run;

proc sgplot data=test sganno=anno pad=(top=30);
scatter x=x y=y;
refline 0 / axis=x;
run;

Re: Title in 2 parts over a graphic with divergent X-axis

ballardw — Thu, 31 Aug 2023 01:23:03 GMT

@Karolus wrote:

The title statement only offers left, right and center, the "left option" sends the "title ABC" way far to the left, the "center option" overlaps the "title XYZ". The title XYZ luckily locates well with the option "right".

You can "pad" text so it appears that things are not all the way to the left

title justify=left "    Some left text" justify=right "And some right text    ";
proc print data=sashelp.class (obs=5);
run;

The "spaces" in the text are actually null, ASCII 255 characters and don't get stripped out the way a simple space might. More of a "something that may work occasionally" then an always do this.

Re: Title in 2 parts over a graphic with divergent X-axis

Ksharp — Thu, 31 Aug 2023 12:15:04 GMT

/*
You could pad some blanks in TITLE
*/

title 'XXXXX                                                 YYYYY';
proc sgplot data=sashelp.heart;
hbar bp_status/response=weight group=sex;
run;

Re: Title in 2 parts over a graphic with divergent X-axis

DanH_sas — Thu, 31 Aug 2023 16:56:58 GMT

Using spaces is an option, particularly is this is a "one-off" graph. However, if this is something you will re-use, possible at different sizes and with different output types, you'll want to use an approach that guarantees that the text will be anchored in the correct location.

Re: Title in 2 parts over a graphic with divergent X-axis

Karolus — Thu, 31 Aug 2023 18:39:30 GMT

Thank you Dan,

an elegant solution, btw, after this I found your paper about annotating graphs, all very useful.

Regards,

Karl