topic Re: Special characters in axis label in Graphics Programming

Special characters in axis label

Celine_France — Mon, 31 Aug 2009 15:45:37 GMT

Hi,

I want to write for example µ in axis labels but it doesn't work.

I keep the label in a macro variable and if I do the instruction put in order to see it in the log, the µ is written but on the graph, there is only °

Here is my code if it can help you :
goptions reset=all ftext=sasmonospace htext=1 ctext=black devmap=winansi keymap=winansi;
axis1 order=&min to &max label=("&x_lab ");
axis2 label=(angle=90 "&y_lab ") order=&min to &max;
symbol1 interpol=join value=none color=blue line=20;
symbol2 interpol=join value=none color=red line=1;
symbol3 interpol=none value='Circle' color=black;

legend1 label=none
mode=reserve
position=(bottom center outside)
offset=(0.5,)
across=3
shape=line(4)
value=('Perfect Concordance Line' 'Observed Concordance Line' ' ');

%macro graphe(yf,xf,minf,maxf);
%if &minf=0 or &maxf=0 %then %do;
proc gplot data=graphe_finale;
plot &yf*&xf Ybissector*i Yobserved*i/ overlay haxis=axis1 vaxis=axis2 legend=legend1 vminor=0 hminor=0 annotate=annoter ;
run;
quit;
%end;
%else %do;
proc gplot data=graphe_finale;
plot Ybissector*i Yobserved*i &yf*&xf/ overlay haxis=axis1 vaxis=axis2 legend=legend1 href=0 vref=0 vminor=0 hminor=0 annotate=annoter ;
run;
quit;
%end;
%mend graphe;
%graphe(&Y,&X,&min,&max)

By advance, thanks a lot,

Céline

Re: Special characters in axis label

DanH_sas — Mon, 31 Aug 2009 19:29:54 GMT

Hey Celine,

Can you give an example of the string assigned to &x_lab or &y_lab?

Thanks!
Dan

Re: Special characters in axis label

Andre — Mon, 31 Aug 2009 21:30:36 GMT

Céline
In sas graph a greek letter is possible
see
http://www.listserv.uga.edu/cgi-bin/wa?A2=ind0806A&L=sas-l&P=R22438&D=1&H=0&O=D&T=1

What i have never tested is their use
inside the axis statement due to another general ftext choice
I never use sasmonospace into sas graphs!

Another question is related to your graph : alone or inside an ods destination?

Andre

Re: Special characters in axis label

ChrisNZ — Tue, 01 Sep 2009 05:36:08 GMT

All valid comments above:
- what is the value of x_lab?
- do you use ODS?
- you must use another font.

You can assess fonts using:

goption ftext=greek;
*goption ftext='arial';
*goption ftext='verdana/bo';

proc gslide;
note height=2 "%sysfunc(getoption(ftext))";
%macro t;
%do i=32 %to 255 %by 32;
note height=2 %do j=&i %to %eval(&i+31); "%sysfunc(byte(&j))" %end; ;
%end;
%mend;%t
run;
quit;

Re: Special characters in axis label

Andre — Tue, 01 Sep 2009 07:29:14 GMT

Celine
(now from work)

See it is working

ods listing close;
ods rtf file="d:\temp\greekfigure.rtf" style=minimal;

goptions device=png rotate=landscape gsflen=132 border htitle=1 htext=1;

proc gplot data=sashelp.class;
title2 font=cgreek height=1.5 'a b c d e f g h i j k l m n o p q r s t u v w x y z';
title3 font=cgreek height=1.5 'A B C D E F G H I J K L M N O P Q R S T U V W X Y Z';
axis1 order=10 to 20 label=(font=swiss "La " font=greek " m" font=swiss " des ados");
plot age * weight/haxis=axis1;
run; quit;
ods rtf close; ods listing;

Re: Special characters in axis label

DanH_sas — Tue, 01 Sep 2009 14:39:11 GMT

Here is yet another possibility. If you are running SAS 9.2, here's a trick you can use with the SG procedures. You can inline unicode character directly in the string. Taking Andre's example:

proc sgplot data=sashelp.class;
xaxis min=10 max=20 label="La (*ESC*){unicode mu} des ados";
scatter x=weight y=age;
run;

Notice that you do not have to change fonts in the middle of the label.

Re: Special characters in axis label

GraphGuy — Tue, 13 Aug 2019 11:34:21 GMT

Here's one way to do it in SAS/Graph gplot axis:

goptions ftext='albany amt' htext=12pt;
axis1 label=("axis label text, with Mu symbol: %SYSFUNC(BYTE(181),$1.) ");
proc gplot data=sashelp.class;
plot height*weight / haxis=axis1;
run;