topic Re: outlineattrs not working in Graphics Programming

outlineattrs not working

agille05 — Thu, 02 Jun 2022 18:52:04 GMT

Hi everyone,

Should be a pretty easy thing to do, but my outlineattrs just isn't working (won't become functional/turn blue). Would appreciate if anyone had any suggestions. See code below.

Proc SGPLOT data=Mitacs.New2;
   histogram age / fillattrs=(color=CX008998) outlineattrs=(color=CXBEBEBE size=1pt);
   xaxis max=100 display=(nolabel);
   yaxis display=(nolabel);
Run;

Thanks!

Re: outlineattrs not working

Reeza — Thu, 02 Jun 2022 19:12:41 GMT

I don't see that option listed in the documentation.

https://documentation.sas.com/doc/en/pgmsascdc/9.4_3.5/grstatproc/n17xrpcduau1f8n1c1nhe477pv18.htm#p131oexgbewkzon18vfvohur7jat

Unfortunately not seeing a way to change the colour. Depending on how important that is, you may want to pipe your code to the GTL code using the TMPLOUT option on PROC SGPLOT and then modify it there.

https://documentation.sas.com/doc/en/pgmsascdc/9.4_3.5/grstatproc/p073bl97jzadkmn15lhq58yiy2uh.htm#n1iqo7vpboefe4n1oysl0yef7633

Re: outlineattrs not working

ballardw — Thu, 02 Jun 2022 19:16:46 GMT

What does your LOG show when you run that?

I don't find OUTLINEATTRS in the options for the HISTOGRAM statement for SGPLOT:

https://documentation.sas.com/doc/en/pgmsascdc/9.4_3.4/grstatproc/n17xrpcduau1f8n1c1nhe477pv18.htm

I think you are trying to use a Graphics Template Language option that belongs in Proc Template code with Sgplot.

Re: outlineattrs not working

agille05 — Thu, 02 Jun 2022 19:30:46 GMT

Thank you! That would explain it. May just have to leave it.

Thank you for taking the time to answer this 🙂

Re: outlineattrs not working

Reeza — Thu, 02 Jun 2022 19:36:13 GMT

Proc SGPLOT data=sashelp.class tmplout='/home/fkhurshed/Demo1/graph_histogram.sas';
   histogram age / fillattrs=(color=CX008998);
   xaxis max=100 display=(nolabel);
   yaxis display=(nolabel);
Run;

*code from graph_histogram code, modifying template name;
proc template;
define statgraph myHistogram;
begingraph / collation=binary;
layout overlay / xaxisopts=( display=( ticks tickvalues line ) type=linear linearopts=( viewmax=100 ) ) y2axisopts=(labelFitPolicy=Split) yaxisopts=( display=( ticks tickvalues line ) labelFitPolicy=Split type=auto ) y2axisopts=(labelFitPolicy=Split);
   Histogram 'Age'n / primary=true binaxis=false FillAttrs=(Color=CX008998) outlineattrs =(color=red) LegendLabel="Age";
endlayout;
endgraph;
end;
run;

proc sgrender data=sashelp.class template=myHistogram;
run;