topic Re: Why does SGPLOT not use a custom format correctly? in Graphics Programming

Why does SGPLOT not use a custom format correctly?

Kurt_Bremser — Wed, 06 Apr 2022 09:25:13 GMT

Consider this picture format:

proc format;
picture myqtr (default=6)
  low-high='%q%Y' (datatype=date)
;
run;

applied to this dataset:

data have;
infile datalines dlm="09"x;
input phase $ patients qtr :yymmdd10.;
format qtr myqtr.;
datalines;
I	5	2021-01-01	
I	10	2021-04-01	
I	14	2021-07-01	
I	8	2022-01-01	
II	20	2021-01-01	
II	30	2021-04-01	
II	66	2021-07-01	
II	55	2022-01-01	
III	60	2021-01-01	
III	70	2021-04-01	
III	78	2021-07-01	
III	67	2022-01-01
;

In the dataset, the dates show nicely as (e.g) Q12021

Now I run PROC SGPLOT:

proc sgplot data=have;
label
  patients = "Patients"
  qtr = "Quarter"
;
vline qtr / response=patients group=phase;
yaxis grid;
run;

and I get this:

Just the format string is used as value.

But when I change the format to a standard SAS format:

proc sgplot data=have;
format qtr yyq7.;
label
  patients = "Patients"
  qtr = "Quarter"
;
vline qtr / response=patients group=phase;
yaxis grid;
run;

I get this:

Does SGPLOT have an issue with custom formats?

Re: Why does SGPLOT not use a custom format correctly?

Kurt_Bremser — Wed, 06 Apr 2022 10:03:44 GMT

Found it. The Graph Template Language cannot deal with the directives of a date, time or datetime picture format:

Unsupported User-Defined Formats

Re: Why does SGPLOT not use a custom format correctly?

Rick_SAS — Wed, 06 Apr 2022 10:21:08 GMT

From Googling this problem, it looks like others have reported similar behavior. See

formatting - SAS proc sgplot with date axis formatted as m/d/yy (i.e. without leading zeros) - Stack Overflow

First, I think you will have more success by keeping a native SAS format. Otherwise, the X axis doesn't know how to handle the spacing for the dates. Remove the FORMAT statement and use the

XAXIS valuesformat=
option to supply a custom format.

Second, it looks like the VALUESFORMAT= option does not work with a PICTURE format, so unfortunately you cannot use

xaxis valuesformat=myqtr.; /* does not work with PICTURE format */

I believe it works for other custom formats, but I have not tested it. Try creating your desired format by using a conventional VALUE statement in PROC FORMAT or by defining an FCMP function.

Re: Why does SGPLOT not use a custom format correctly?

Kurt_Bremser — Wed, 06 Apr 2022 10:23:58 GMT

Custom formats work, but not picture formats that use directives. I have not looked into this, but I suspect that the directive notation would interfere with the GTL syntax (the % character is the usual suspect here).

Re: Why does SGPLOT not use a custom format correctly?

Kurt_Bremser — Wed, 06 Apr 2022 10:36:47 GMT

Native formats are no problem at all, but a user wanted to have a different notation of quarters that is not covered by a standard SAS format, see in this thread: https://communities.sas.com/t5/SAS-Programming/How-to-depict-quarters-of-the-year-on-the-x-axis/td-p/806000/jump-to/first-unread-message

It would still be nice, though, to have all elements in SAS treat all formats the same, consistently. After all, it took me (and I'm no SAS newbie) considerable effort to find the reason for the non-function. And, IMHO, as a customer of SAS one would expect the software to be consistent throughout with the use of formats. I consider this expectance part of the big bucks people pay for SAS.

PS Da haben sich die Designer nicht mit Ruhm bekleckert.

("The designers did not exactly cover themselves with glory")

Re: Why does SGPLOT not use a custom format correctly?

ballardw — Wed, 06 Apr 2022 14:36:57 GMT

I might suggest using a function created in FCMP to produce a string value for the target of a format.

Of course that adds another level of headache to code maintenance but the things we do for customers...