topic Re: Change barwidth sgplot histogram in Graphics Programming

Change barwidth sgplot histogram

Anita_n — Mon, 26 Apr 2021 10:50:32 GMT

Hi all,

is there any way to change the barwidth

in sgplot histogram statement?

Re: Change barwidth sgplot histogram

PaigeMiller — Mon, 26 Apr 2021 11:00:06 GMT

use the BINWIDTH= option

https://documentation.sas.com/doc/en/pgmsascdc/9.4_3.4/grstatproc/n17xrpcduau1f8n1c1nhe477pv18.htm#p10yvray7y3xs8n1go4hfvht8fzj

Re: Change barwidth sgplot histogram

Anita_n — Mon, 26 Apr 2021 11:36:46 GMT

Hi thanks, is binwidth=barwidth. This is not giving me the right results, even if I use even when I use

binwidth= binstart= showbins

Re: Change barwidth sgplot histogram

PaigeMiller — Mon, 26 Apr 2021 11:41:42 GMT

@Anita_n wrote:

Hi thanks, is binwidth=barwidth. This is not giving me the right results, even if I use even when I use

binwidth= binstart= showbins

Explain further. What is not giving you the right results? What isn't right about them? Show us your code. Show us your output.

Re: Change barwidth sgplot histogram

Anita_n — Mon, 26 Apr 2021 12:02:04 GMT

@PaigeMiller


proc sgplot data=sashelp.heart;
where sex=:'F';
histogram agechddiag / fillattrs=(color=pink);
run;

/*After adding binwidth*/
proc sgplot data=sashelp.heart;
where sex=:'F';
histogram agechddiag / fillattrs=(color=pink) binwidth=5 binstart=50 showbins;
run;

Re: Change barwidth sgplot histogram

PaigeMiller — Mon, 26 Apr 2021 12:05:44 GMT

Please explain what is wrong with the plot, and what you would like to see.

Re: Change barwidth sgplot histogram

Ksharp — Mon, 26 Apr 2021 12:19:03 GMT

ods select histogram;
proc univariate data=sashelp.heart ;
where sex=:'F';
var agechddiag ;
histogram agechddiag / kernel  barwidth=1; 
run;

proc univariate data=sashelp.heart ;
where sex=:'F';
var agechddiag ;
histogram agechddiag / kernel  endpoints=(30 to 100 by 20)  ;
run;

Re: Change barwidth sgplot histogram

Ksharp — Mon, 26 Apr 2021 12:24:42 GMT



proc sgplot data=sashelp.heart;
where sex=:'F';
histogram agechddiag / fillattrs=(color=pink) nbins=10  showbins;
run;

proc sgplot data=sashelp.heart;
where sex=:'F';
histogram agechddiag / fillattrs=(color=pink) nbins=5  showbins;
run;

Re: Change barwidth sgplot histogram

Anita_n — Mon, 26 Apr 2021 13:24:23 GMT

what does this nbins really do? I just wanted to reduce the size of the bars like when using barwidth=0.9 or barwidth=0.6

Re: Change barwidth sgplot histogram

DanH_sas — Mon, 26 Apr 2021 13:36:21 GMT

In a histogram, the bar width is data-driven. The width of the bar shows the range of values included in the bin. By changing the number of bins (NBINS), you change the range of values in each bin. The more bins you have, the thinner the bars will be.

Re: Change barwidth sgplot histogram

Anita_n — Mon, 26 Apr 2021 15:06:02 GMT

Okay , thanks I now understand how it works

Re: Change barwidth sgplot histogram

GraphGuy — Wed, 28 Apr 2021 16:34:13 GMT

If I understand your question, you want to control the physical width of the bars (not the 'width' of the data bin - ie, not the range of values in each bar) ? ...

In sgplot histograms, I believe the physical width of the bars expands to fill most/all available space. Therefore one way to control the physical width of the bars would be to change the width of the page. (But you probably don't want that.)

You can also add more 'offset' between the bars and the axes, using the xaxis offsetmin= and offsetmax= options, to 'squeeze' the bars into a smaller space and make them 'skinnier' (offsetmin controls the space on the left side, and offsetmax controls the right side). Here's an example, without and with the offsetmin and offsetmax options:

/* default, with no offsetmin/offsetmax specified */

proc sgplot data=sashelp.heart;
where sex=:'F';
histogram agechddiag / nbins=7 fillattrs=(color=pink);
run;

proc sgplot data=sashelp.heart;
where sex=:'F';
histogram agechddiag / nbins=7 fillattrs=(color=pink);
xaxis offsetmin=.2 offsetmax=.2;
run;

Re: Change barwidth sgplot histogram

Anita_n — Thu, 29 Apr 2021 08:00:22 GMT

@GraphGuy yes, that is exactly what I wanted. Thanks