topic Re: sgplot: using data response and datalabel in Graphics Programming

sgplot: using data response and datalabel

Anita_n — Mon, 19 Apr 2021 11:01:12 GMT

Hi all,

Is it possible to specify a response and a different datalabel in sgplot. I mean I wish to display the relative (percent) values on the yaxis but the absolute on that bars. I used the following code but the pecentages are display in both cases. Is it possible to do that anyway?

proc sgplot data =mergedat dattrmap=myattrimap pad=(bottom=5%) noautolegend noborder;
xaxis grid type=discrete discreteorder=data;
vbar year response=percentvar group=grup attrid=grup  datalabel = absolutevar datalabelattrs=(weight=bold) seglabel seglabelattrs=(size=0.25) 
seglabelfitpolicy=none barwidth=0.9 missing;
xaxis  display= (nolabel) valueattrs=(family="verdana" size=8pt) fitpolicy=rotate ValuesRotate=Vertical;
yaxis values=(0 to 60  by 10) display= (nolabel) valueattrs=(family="verdana" size=8pt);

run;

Re: sgplot: using data response and datalabel

Ksharp — Mon, 19 Apr 2021 12:00:56 GMT

You code looks good . What you want to try ?

proc sql;
create table want as
select age,sex,sum(weight) as sum,calculated sum/(select sum(weight) from sashelp.class where sex=a.sex) as per format=percent8.2
 from sashelp.class as a
  group by age,sex;
quit;
proc sgplot data=want;
vbarparm category=age response=per/group=sex datalabel=sum;
run;

Re: sgplot: using data response and datalabel

ballardw — Mon, 19 Apr 2021 14:52:56 GMT

Show the code from the log.
Your code as posted will throw at least one error because of a missing / option indicator.

Data is nice.

Re: sgplot: using data response and datalabel

Anita_n — Mon, 19 Apr 2021 14:54:29 GMT

@Ksharp thanks for the Code but the bars aren't labelled

Re: sgplot: using data response and datalabel

Anita_n — Mon, 19 Apr 2021 14:57:09 GMT

@ballardw I have no error in the log. The problem is that it uses the percent instead of the absolute values although I indicated datalabel= absolute value

Re: sgplot: using data response and datalabel

Jay54 — Mon, 19 Apr 2021 15:11:07 GMT

In @Ksharp code, add option GROUPDISPLAY=cluster to VBARPARM stmt see the data labels.

See doc for DATALABEL that says this is displayed only when groups are clustered, not stacked.

https://documentation.sas.com/doc/en/pgmsascdc/9.4_3.5/grstatproc/n0mc5dtithid5mn13c54dlgaceq3.htm#p14nwead434yo5n0zxw4gb9zpul9d

If you want label for each bar segment, use SEGLABEL option.

https://documentation.sas.com/doc/en/pgmsascdc/9.4_3.5/grstatproc/n0mc5dtithid5mn13c54dlgaceq3.htm#n0f9e89gx8pqjen1muljrgq8n4r6f

https://blogs.sas.com/content/graphicallyspeaking/2013/09/20/stacked-bar-chart-with-segment-labels/

Re: sgplot: using data response and datalabel

Anita_n — Mon, 19 Apr 2021 15:14:08 GMT

@Jay54 that displays the bars side by side. I wouldn't like to display them as clusters

Re: sgplot: using data response and datalabel

Jay54 — Mon, 19 Apr 2021 15:55:02 GMT

In ODS Graphics parlance, side-by-side is called "Clustered". Default group display is stacked. For labels on all stacked segments, use SEGLABEL option.

Example:

title 'Product Sales by Country';
proc sgplot data=sashelp.prdsale noborder;
    format actual dollar8.0;
    vbar country / response=actual group=product displaybaseline=auto barwidth=0.6
            seglabel datalabel dataskin=pressed;
    xaxis display=(noline noticks nolabel);
    yaxis display=(noline noticks nolabel) grid;
    keylegend / location=outside fillheight=10 fillaspect=2 ;
run;

Re: sgplot: using data response and datalabel

GraphGuy — Mon, 19 Apr 2021 16:55:27 GMT

Can you post your data, so we can experiment with it?

Re: sgplot: using data response and datalabel

Ksharp — Tue, 20 Apr 2021 12:20:45 GMT

proc sql;
create table want as
select age,sex,sum(weight) as sum,calculated sum/(select sum(weight) from sashelp.class where sex=a.sex) as per format=percent8.2
 from sashelp.class as a
  group by age,sex
   order by age,sex;
quit;
data want;
 set want;
 by age;
 retain lag;
 if first.age then lag=0;
 mean=lag+per/2;
 lag=per;
run;


proc sgplot data=want;
vbarparm category=age response=per/group=sex GROUPDISPLAY=stack;
scatter x=age y=mean / markerchar=sum;
run;

You want this one ?

Re: sgplot: using data response and datalabel

Anita_n — Tue, 20 Apr 2021 12:43:57 GMT

Hi @all : Thankyou all for your suggestions.

@Ksharp Since I already used vbar, I taught I could continue with it.

@Jay54 I tried that code but it still writes the percentage values in the segment, I wanted instead the absolute values

@GraphGuy I have attached a sample data and my code

proc sgplot data =t.test4 pad=(bottom=5%) noautolegend noborder;
xaxis grid type=discrete discreteorder=data;
vbar date /response=freq group=var1 attrid=var1  seglabel seglabelattrs=(size=0.25) 
seglabelfitpolicy=none barwidth=0.6 missing;
xaxis  display= (nolabel) valueattrs=(family="verdana" size=8pt) fitpolicy=rotate ValuesRotate=Vertical;
yaxis  display= (nolabel) valueattrs=(family="verdana" size=8pt);

run;

Re: sgplot: using data response and datalabel

Ksharp — Tue, 20 Apr 2021 13:08:09 GMT

proc sql;
create table want as
select date,var1,sum(var2) as sum,calculated sum/(select sum(var2) from x.test4 where date=a.date) as per format=percent8.2
 from x.test4 as a
  group by date,var1
   order by date,var1;
quit;
data want;
 set want;
 by date;
 if first.date then lag=0;
 mean=lag+per/2;
 lag+per;
run;


proc sgplot data=want;
vbarparm category=date response=per/group=var1 GROUPDISPLAY=stack;
scatter x=date y=mean / markerchar=sum;
run;

Re: sgplot: using data response and datalabel

Anita_n — Tue, 20 Apr 2021 13:16:12 GMT

okay, is this not possible with vbar

Re: sgplot: using data response and datalabel

Ksharp — Tue, 20 Apr 2021 13:17:31 GMT

Or could be simpler. I see your data has been orgonized very well.

data want;
 set x.test4;
 by date;
 if first.date then lag=0;
 mean=lag+freq/2;
 lag+freq;
run;


proc sgplot data=want;
vbarparm category=date response=freq/group=var1 GROUPDISPLAY=stack;
scatter x=date y=mean / markerchar=var2;
run;

Re: sgplot: using data response and datalabel

Ksharp — Tue, 20 Apr 2021 13:21:12 GMT


data want;
 set x.test4;
 by date;
 if first.date then lag=0;
 mean=lag+freq/2;
 lag+freq;
run;


proc sgplot data=want;
vbarbasic date /response=freq group=var1 GROUPDISPLAY=stack;
scatter x=date y=mean / markerchar=var2;
run;

If you really want VBAR ,try this one .

Re: sgplot: using data response and datalabel

Anita_n — Tue, 20 Apr 2021 20:23:59 GMT

@Ksharp what is the difference between the vbar statement and the vbarparm statement?

Re: sgplot: using data response and datalabel

DanH_sas — Tue, 20 Apr 2021 20:41:17 GMT

VBAR statement will compute the summary statistics for you. The VBARPARM is for pre-summarized data. The VBARPARM statement has more flexibility with the type of plots statements that it can be overlaid with it.

Re: sgplot: using data response and datalabel

Anita_n — Wed, 21 Apr 2021 06:10:49 GMT

Thankyou

Re: sgplot: using data response and datalabel

Ksharp — Wed, 21 Apr 2021 12:07:32 GMT

@Rick_SAS wrote an excellent blog about this topic . You can ask him .

https://blogs.sas.com/content/iml/2021/04/14/overlay-graphs-basic-bar-chart.html