topic Re: Creating Custom legend in Graphics Programming

Creating Custom legend

RandoDando — Wed, 07 Apr 2021 18:13:17 GMT

I need a way to produce only a legend which can be used on a panel in a template I have created. It's nothing fancy, just a title, 4 colored squares (with Hex or color name specified) with some text next to each. I've seen some SAS programming use gplot to produce only a legend, but that isn't working for my purposes. I came across Lex Jansen's page on it, but wasn't able to use that either. Anyone have some canned SAS code that will do this? I just need a way to call it in PROC GREPLAY so that I can add it to a template.

Re: Creating Custom legend

ballardw — Wed, 07 Apr 2021 18:56:18 GMT

It may help to show the "template" you have created so we have some idea what you are working with.

It would likely be a good idea to show what a completed graph with this might look like and the bits that you are asking for highlighted.

Re: Creating Custom legend

Reeza — Wed, 07 Apr 2021 19:15:19 GMT

Are you using GTL, SGPLOT or GPLOT? Or something else? That will matter....

Re: Creating Custom legend

RandoDando — Wed, 07 Apr 2021 19:20:02 GMT

I am using GMAP (nolegend option) and GSLIDE outputs on the template.
Legend would apply to the GMAP outputs universally.

Re: Creating Custom legend

Reeza — Wed, 07 Apr 2021 19:25:06 GMT

Ok. I think I don't know enough to answer your question. I would have assumed that you could just use GMAP and then get the legend within there customized. I would use formats to get the hex code shown as desired instead of the labels.
https://robslink.com/SAS/democd66/aaaindex.htm

Either way, I've moved this post to the graphics forum so hopefully one of the graphics guru's can assist you soon 🙂

FYI - SGMAP makes much better maps these days.

Re: Creating Custom legend

Jay54 — Wed, 07 Apr 2021 19:59:22 GMT

This should be doable using SGPLOT procedure with a "dummy" scatter plot statement and sashelp.class. The dummy plot is needed to allow the plot output to be created. Transparency=1 can be used to suppress any actual plot display. Other options can be used to suppress axes and borders.

Then, use one or more LEGENDITEM statements to define named legend entries you need, including color, type of item and the associated text. Then, add the names of the legend items to the KEYLEGEND statement.

You can do the same with GTL too.

See use of LegendItem in this example:

https://blogs.sas.com/content/graphicallyspeaking/2017/10/27/legend-items/

Also see documentation:

https://documentation.sas.com/?cdcId=pgmsascdc&cdcVersion=9.4_3.5&docsetId=grstatproc&docsetTarget=p0hc32jtfqoy1fn1h5i38q8v9py2.htm&locale=en

https://documentation.sas.com/?cdcId=pgmsascdc&cdcVersion=9.4_3.5&docsetId=grstatproc&docsetTarget=p0xmbppzx71smbn1203aaif96z86.htm&locale=en

Re: Creating Custom legend

Jay54 — Wed, 07 Apr 2021 22:43:42 GMT

Here is an example:

ods graphics / noborder;
proc sgplot data=sashelp.class noborder;
scatter x=height y=weight / group=sex transparency=1;
xaxis display=none;
yaxis display=none;
legenditem type=fill name='Item1' / fillattrs=graphdata2 label='Custom 1';
legenditem type=line name='Item2' / lineattrs=graphdata3 label='Custom 2';
keylegend 'Item1' 'Item2' / scale=2;
run;

Re: Creating Custom legend

RandoDando — Thu, 08 Apr 2021 12:01:22 GMT

Oh no.

Was the LEGENDITEM option added recently? When I copy this code and run it those options appear in red and I get an invalid statement error for those.

Looks like we may have to call upon the macro gurus...

Re: Creating Custom legend

GraphGuy — Thu, 08 Apr 2021 12:23:44 GMT

Since you're using SAS/Graph (gmap, gslide, greplay), you will not be able to easily use ODS Graphics (sgplot) with it.

One solution I've used to get a second legend on a separate page in SAS/Graph is to suppress the legend in the real graph (nolegend), and then use 'annotate' on a blank gslide to fabricate my own custom legend on a separate page. Here's an example - the outtput, and then the code:

http://robslink.com/SAS/democd16/topper.htm

http://robslink.com/SAS/democd16/topper.sas

Re: Creating Custom legend

GraphGuy — Thu, 08 Apr 2021 13:04:07 GMT

If you don't want to go with creating a custom legend with annotate, here's a way you might use a gplot legend... This example creates a gmap and suppresses the gmap legend, then creates a gplot using the same data (keeping the gplot legend, basically suppressing the gplot graph). You'll probably have some variable other than statecode to color the graphs by.

I only played around with this for a few minutes - you can probably make some improvements! 🙂

data foo; set sashelp.us_data (where=(statecode in ('NC' 'SC' 'GA')));
run;

goptions xpixels=500 ypixels=500;
proc gmap data=foo map=maps.us;
id statecode;
choro statecode / discrete nolegend;
run;

symbol1 font='albany amt/unicode' value='25a0'x interpol=none h=.00001;
legend1 label=('My Legend') shape=symbol(.25in,.25in) repeat=1;
title; footnote;
goptions xpixels=600 ypixels=50;
proc gplot data=foo;
plot population_2010*population_2010=statecode / legend=legend1
noaxes noframe;
run;

Re: Creating Custom legend

RandoDando — Thu, 08 Apr 2021 13:29:43 GMT

Thanks, Rob! That did the trick/