topic Re: Stacked bar graph of column percentages for subgroups in Graphics Programming

Stacked bar graph of column percentages for subgroups

Jason2020 — Tue, 23 Mar 2021 23:27:53 GMT

Greetings,

I have a data set of a survey, and the program below generates a stacked bar graph of the percentage of DISEASE status (3 categories) by LOCATION. However, the graph uses the percentages of the total sample, whereas I want the graph to show the column percentages, and only for diseased individuals.

I tried using WHERE statement to include only the diseased groups, but the percentages becomes wrong. Is there a way around that?

ods graphics on;

proc surveyfreq data=moroc6 order=formatted;

tables disease * location /col nowt nototal plots= freqplot(groupby=column twoway=stacked scale=percent);

where disease in ("Acute" , "Chron" , "None");

cluster province;

strata region;

weight sampling_weight;

run;

ods graphics off;

Re: Stacked bar graph of column percentages for subgroups

Watts — Wed, 24 Mar 2021 03:46:37 GMT

To display column percentages (instead of overall percentages) in a stacked bar chart, you can use the SCALE=GROUPPERCENT plot-option in PROC FREQ.

proc freq data=moroc6;
   tables disease * location / plots=freqplot(scale=grouppercent twoway=stacked);
   weight sampling_weight;
run;

For a stacked bar chart (which doesn't display standard errors or confidence limits), you can use PROC FREQ instead of PROC SURVEYFREQ; specify the same WEIGHT statement in PROC FREQ (to produce the same estimates of frequencies and percentages that PROC SURVEYFREQ produces).

Yes, the column percentages (which are percentages of the column totals) will be different if you exclude the Disease='None' cases.

Re: Stacked bar graph of column percentages for subgroups

Jason2020 — Wed, 24 Mar 2021 13:00:01 GMT

Thank you for the solution. I now can see that Proc Freq can produce a plot of column percentages (it is odd that surveyfreq couldn't). Although this is useful, it doesn't solve my other issue (i.e., select only diseased subjects, without changing the column percentages). I therefore will modify my question.

The following program will output a subset of the column percentages to a new data set (see print out below). Can someone please direct me to which procedure will make the stacked plot, preferably if you can suggest the statement that will do the task. Thanks in advance.

proc surveyfreq data=moroc6 order=formatted;
tables disease * location /col nowt;
cluster province;
strata region;
weight sampling_weight;
ods output crosstabs = Table1 (keep =disease location colPercent);
run;

proc print data=table1;
where (disease ="Acute" or disease ="Chron") and location ne " ";
format colpercent 6.1;
run;

Re: Stacked bar graph of column percentages for subgroups

Jason2020 — Wed, 24 Mar 2021 14:52:33 GMT

Actually did some research and found the solution:

proc sgplot data=table1 (where= ((disease ="Acute" or disease ="Chron") and location ne " "));
format colpercent 6.1;
vbar location / response=colpercent group=disease;
xaxis display=(nolabel);
yaxis grid;
run;