topic Re: Proc Univariate - Histogram options - Specify Color bar & Title/Description in Graphics Programming

Histogram options - Specify Color bar & Title/Description

IChatterji — Fri, 05 Mar 2021 18:26:12 GMT

Hello,

I am using the following code to create Histograms that I will ultimately include in a presentation package. I need to format the titles and color bars so that it matches the rest of the presentation template. My 2 needs are :

- What is the code to specify the color that is filled in the histogram bar?

- What is the code to display the BY variables in the Plot Description? Currently the histogram description is "Distribution of PnL". I want to be able to say "Distribution of PnL - <Symbol>_<RiskProfile>"

Any suggestions would be greatly appreciated. If this question should be posted in Graphics community, please let me know.

ods select Histogram;
proc univariate data=Mstr_rule4a_analysis noprint;
by symbol riskprofile;
var PnL;
histogram/barlabel=count ;
where win_loss ne 'FEE' and year ge 2015 ;
inset n mean std="Std Dev" / pos = ne format = 5.2;
title 'IB One-5yrs-Histogram PnL';
run;
title;

Re: Proc Univariate - Histogram options - Specify Color bar & Title/Description

Reeza — Thu, 04 Mar 2021 21:07:43 GMT

You can control it somewhat using the different style templates but PROC UNIVARIATE doesn't offer much customization options.

If you're looking for a fully customized graph, I would highly suggest using SGPLOT histogram code instead.

https://blogs.sas.com/content/graphicallyspeaking/2017/04/30/getting-started-with-sgplot-histograms/

You would use FILL/FILLATTRS option on the HISTOGRAM statement to control the colours.
https://documentation.sas.com/?cdcId=pgmsascdc&cdcVersion=9.4_3.5&docsetId=grstatproc&docsetTarget=n17xrpcduau1f8n1c1nhe477pv18.htm&locale=en

Re: Proc Univariate - Histogram options - Specify Color bar & Title/Description

IChatterji — Thu, 04 Mar 2021 21:55:47 GMT

Thank you. I will try my hand at SGPLOT. Are questions on SGPLOT best directed to the Graphics community?

Re: Proc Univariate - Histogram options - Specify Color bar & Title/Description

Reeza — Thu, 04 Mar 2021 22:23:00 GMT

Yes, any graphics related questions are best posted there.

Re: Proc Univariate - Histogram options - Specify Color bar & Title/Description

Rick_SAS — Fri, 05 Mar 2021 18:24:16 GMT

For the title, use the ODSTITLE= option in conjunction with the #BYVAL keyword. If you aren't familiar with the #BYVAL keyword, see "How to use the #BYVAR and #BYVAL keywords."

options nobyline;

proc univariate ...;
ods select Histogram;
by symbol riskprofile;
var PnL;
histogram PnL / odstitle="Distribution of PnL - #ByVal1._#ByVal2";
...
run;

options byline;

Even if you switch to PROC SGPLOT (which I agree is a good idea), you can also use the #BYVAL keyword to control the TITLE statement used for your PROC SGPLOT graphs.

Re: Proc Univariate - Histogram options - Specify Color bar & Title/Description

IChatterji — Fri, 05 Mar 2021 19:09:58 GMT

Thank you Rick. The #ByVal<n> option works very well, I am a bit embarrassed that it was not known to me as this was available in SAS since 1998! I am attaching below my final code in case any reader wants to view the before/after code change.

options byline;
ods select Histogram;
proc univariate data=Mstr_rule4a_analysis noprint;
by symbol riskprofile;
var PnL;
histogram/barlabel=count odstitle="Distribution of PnL - #ByVal1._#ByVal2";
where win_loss ne 'FEE' and year ge 2015 ;
inset n mean std="Std Dev" / pos = ne format = 5.2;
title 'IB One-5yrs-Histogram PnL';
run;
title;
options nobyline;

Do you by any chance have a suggestion for how to change the colors in the histogram bars without going to SGPLOT?

Re: Proc Univariate - Histogram options - Specify Color bar & Title/Description

Rick_SAS — Fri, 05 Mar 2021 19:29:32 GMT

The colors in SAS graphs are determined by the current ODS style. You can create a new style and specify the color that is used to fill bars (and other graph attributes). There is a whole chapter in the SAS/STAT documentation about how to understand and modify ODS styles.

Personally, I think it will be easier for you to use SGPLOT. Here is an example so you can see how it is done:

proc sort data=sashelp.cars(where=(type in ('Sedan' 'Wagon' 'SUV'))) out=cars;
by origin type;
run;

options nobyline;

title "Distribution of MPG City - #ByVal1._#ByVal2";
proc sgplot data=cars;
by origin type;
histogram MPG_City / fillattrs=(color=VeryLightYellow); /* or color=CXFAFAA0 */
run;

options byline;