topic Re: add table of values below sgplot in Graphics Programming

Add table with values under sgplot

mmea — Thu, 21 Jan 2021 21:07:02 GMT

Hi i have data like this

METHOD	DAYS
A	0
B	1
A	0
C	2
C	0
A	4
B	1
C	0
B	0
A	0

And sgplot like this:

proc format;
    value days 
  0='Same day'  
  1='Next day' 
  2-3 = '+2 days'  
  4-high = '+4 days';
run;


PROC SGPLOT DATA = Merged_1 PCTLEVEL=GROUP NOBORDER NOWALL NOCYCLEATTRS ;
format dato ddmmyy.;
VBAR METHOD / GROUP = days stat= percent NOOUTLINE;       
TITLE 'TEST';
keylegend / title="";
XAXIS DISPLAY=(NOLABEL);
YAXIS DISPLAY=(NOLABEL);
format days days.;
styleattrs DATACOLORS=('#CBE5A1' '#FFFF00' mistyrose firebrick );
run;

I want a table under the sgplot that looks like this - the count of how many same day, next day etc.:

	A	B	C
Same day	3	1	2
next day	0	2	0
+2 days	0	0	1
+4 days	1	0	0

Hope you can help

add table of values below sgplot

mmea — Fri, 22 Jan 2021 08:06:18 GMT

Se the first post

Re: add table of values below sgplot

Reeza — Wed, 20 Jan 2021 16:47:31 GMT

XAXISTABLE, see example at the bottom of the documentation.

I'd first try adding this code to my PROC
xaxistable Days / stat=freq;

https://documentation.sas.com/?cdcId=pgmsascdc&cdcVersion=9.4_3.5&docsetId=grstatproc&docsetTarget=p1cebnxst19wccn1s44lyk5nk2vx.htm&locale=en#n0y9pvt4szfsrhn1wnijfnb3zygn

Re: add table of values below sgplot

mmea — Thu, 21 Jan 2021 08:47:32 GMT


proc format;
    value days 
  0='Same day'  
  1='Next day' 
  2-3 = '+2 '  
  4-high = '+4 ';
run;



PROC SGPLOT DATA = comp PCTLEVEL=GROUP NOBORDER NOWALL NOCYCLEATTRS ;
format dato ddmmyy.;
VBAR method / GROUP = days stat= percent NOOUTLINE;       
TITLE 'A';
keylegend / title="";
XAXIS DISPLAY=(NOLABEL);
YAXIS DISPLAY=(NOLABEL);


FORMAT days days.;
styleattrs DATACOLORS=('#CBE5A1' '#FFFF00' mistyrose firebrick );
run;

It doesnt work 🙂

It messes up the plot

Re: add table of values below sgplot

Reeza — Thu, 21 Jan 2021 17:00:28 GMT

Does not work is vague and uninformative.

If you want help with the actual code provide sample data, your code and log. The code shown does not include an XAXISTABLE so obviously it wouldn't work but I have no idea what you tried or did.

Re: add table of values below sgplot

Reeza — Thu, 21 Jan 2021 21:15:35 GMT

Not really sure why you started a new thread but I've merged the two.

Re: add table of values below sgplot

mmea — Fri, 22 Jan 2021 12:01:01 GMT

when I put xaxistable Days;


proc format;
    value days 
  0='Same day'  
  1='Next day' 
  2-3 = '+2 days'  
  4-high = '+4 days';
run;

PROC SGPLOT DATA = Merged_1 PCTLEVEL=GROUP NOBORDER NOWALL NOCYCLEATTRS ;
format date ddmmyy.;
VBAR method/GROUP = days stat= percent NOOUTLINE;       
TITLE 'tets';
keylegend / title="";
XAXIS DISPLAY=(NOLABEL);
YAXIS DISPLAY=(NOLABEL);
FORMAT days days.;
xaxistable Days;
styleattrs DATACOLORS=('#CBE5A1' '#FFFF00' mistyrose firebrick );
run;

it gives me this


same day	same day	same day	same day
next day	+4 days	+2 days	+4 days
+2 days	+4 days	+4days	+4 days
+4 days	+4days		+4days

which is not correct.

The table should count the days value shown in the table in the question?

How can i do that

Re: add table of values below sgplot

mmea — Sun, 24 Jan 2021 15:34:15 GMT

Is there no help to get here ?

Re: add table of values below sgplot

Reeza — Mon, 25 Jan 2021 04:23:50 GMT

Moved your post to the graphics forum.
Perhaps someone will be able to answer there.

Re: Add table with values under sgplot

GraphGuy — Wed, 27 Jan 2021 12:31:40 GMT

Looks like your data needs some manipulation/summarization in order to print the table you're wanting. There might be a slick/automated way to do that with proc tabulate or something ... but here's one way to do it with "brute force" ...

data merged_1;
length method $1;
input method days;
datalines;
A 0
B 1
A 0
C 2
C 0
A 4
B 1
C 0
B 0
A 0
;
run;

proc format;
value days
0='Same day'
1='Next day'
2-3 = '+2 days'
4-high = '+4 days';
run;

PROC SGPLOT DATA = Merged_1 PCTLEVEL=GROUP NOBORDER NOWALL NOCYCLEATTRS ;
VBAR METHOD / GROUP = days stat= percent NOOUTLINE;
TITLE 'TEST';
keylegend / title="";
XAXIS DISPLAY=(NOLABEL);
YAXIS DISPLAY=(NOLABEL);
format days days.;
styleattrs DATACOLORS=('#CBE5A1' '#FFFF00' mistyrose firebrick );
run;

proc sql noprint;
create table summary_table as
select unique method, days, count(*) as count
from merged_1
group by method, days;
quit; run;
proc sort data=summary_table out=summary_table;
by days;
run;
proc transpose data=summary_table out=summary_table;
by days;
id method;
run;
proc print data=summary_table (drop=_name_) label noobs;
label days='00'x;
format days days.;
run;

Re: Add table with values under sgplot

mmea — Wed, 27 Jan 2021 15:37:08 GMT

Thank you can I make the sgplot and table as one PNG?

Re: add table of values below sgplot

Reeza — Wed, 27 Jan 2021 16:15:28 GMT

data merged_1;
length method $1;
input method days;
datalines;
A 0
B 1
A 0
C 2
C 0
A 4
B 1
C 0
B 0
A 0
;
run;

 

proc format;
value days
0='Same day'
1='Next day'
2-3 = '+2 days'
4-high = '+4 days';
run;

proc freq data=merged_1 noprint;
table method*days / out=summarized sparse;
format days days.;
run;
 

PROC SGPLOT DATA = summarized PCTLEVEL=GROUP NOBORDER NOWALL NOCYCLEATTRS ;
VBAR  METHOD / response = count GROUP = days  NOOUTLINE;

keylegend / title="";
XAXIS DISPLAY=(NOLABEL);
YAXIS DISPLAY=(NOLABEL);
styleattrs DATACOLORS=('#CBE5A1' '#FFFF00' mistyrose firebrick );
xaxistable count  ;
format days days.;
run;

This works for me, I pre-summarized the data and followed this blog post:

https://blogs.sas.com/content/graphicallyspeaking/2017/04/04/consistent-ordering-graph-components/