topic Reference line using date with yymmn6 format in Graphics Programming

Reference line using date with yymmn6 format

AnkaS — Wed, 18 Nov 2020 12:49:14 GMT

I'm using sgplot and am trying to add a reference line for a certain month (march 2020) when I have the x-axis variable formated as yymmn6. However, using this sample code I get the following warning:

WARNING: X='202003' is invalid. The plot will not be drawn. Which gives me the plot, without the reference line. How do I formulate the refline statement to get my line to show up?

data test;
input monthno count;
datalines;
202001 78
202002 67
202003 99
202004 56
202005 63
202006 82
;
run;

data test;
set test;
time=input(put(monthno,6.),yymmn6.);
format time yymmn6.;
run;

proc sgplot data= test;
	yaxis label="Amount";
	xaxis label="Month";
	series x=time y=count;
	refline '202003' /axis=x;
run;

Re: Reference line using date with yymmn6 format

Ksharp — Wed, 18 Nov 2020 12:52:10 GMT

Try;

refline '1mar2020'd /axis=x;

Re: Reference line using date with yymmn6 format

PaigeMiller — Wed, 18 Nov 2020 12:55:01 GMT

You can't specify a character variable value in this case for the X axis, which is numeric. You need to specify a numeric value, which in this case is 01MAR2020

refline '01MAR2020'd /axis=x;

Re: Reference line using date with yymmn6 format

PeterClemmensen — Wed, 18 Nov 2020 12:58:28 GMT

Use a Date Constant

proc sgplot data= test;
	yaxis label="Amount";
	xaxis label="Month";
	series x=time y=count;
	refline "01mar2020"d /axis=x;
run;

Re: Reference line using date with yymmn6 format

FreelanceReinh — Wed, 18 Nov 2020 13:45:03 GMT

Hello @AnkaS and welcome to the SAS Support Communities!

My first thought was also to specify a date literal or other numeric value, but it turned out that your formatted value '202003' works better if you add the option type=discrete to the XAXIS statement:

xaxis label="Month" type=discrete;

Without this option the x-axis tick mark labels did not even honor the YYMMN6. format in my SAS session, but were displayed in an "automatically generated" format, as a note in the log said.

(Edit: Changing the axis type to "discrete" would of course change the appearance of the graph if the monthno values weren't equidistant.)

Re: Reference line using date with yymmn6 format

AnkaS — Thu, 19 Nov 2020 13:24:19 GMT

Thank you, all. That solved it.