topic Re: sgplot : scatter plot with connected mean in Graphics Programming

sgplot : scatter plot with connected mean

Golf — Sat, 18 Jul 2020 04:06:25 GMT

Hello,

I have two variables pref_hat and BrewingTime (2 mins, 4 mins, 6mins and 8mins). I used the following procedure:

proc sgplot data = conjoint;
scatter y=pref_hat x=BrewingTime;
run;

How can I connect the mean of pref_hat in each of BrewingTime in the scatter plot below?

Bests,

Golf

Re: sgplot : scatter plot with connected mean

FreelanceReinh — Sat, 18 Jul 2020 10:52:15 GMT

Hello @Golf,

I would combine the scatter plot with a line plot using precomputed mean values:

/* Create test data for demonstration */

data conjoint(drop=b);
length BrewingTime $8;
do _n_=1 to 9;
  pref_hat=0.3+0.4*rannor(1425674559);
  do b=2 to 8 by 2;
    pref_hat=pref_hat+b/18-b**2/65;
    BrewingTime=catx(' ',b,'Mins');
    output;
  end;
end;
run;

/* Compute mean values */

proc summary data=conjoint nway;
class BrewingTime;
var pref_hat;
output out=stats mean=mean_pref_hat;
run;

/* Append mean values to detail data */

data want;
set conjoint stats;
run;

/* Combine scatter plot with line plot */

proc sgplot data=want;
scatter y=pref_hat      x=BrewingTime;
series  y=mean_pref_hat x=BrewingTime / markers markerattrs=(symbol=X);
run;

Result:

Re: sgplot : scatter plot with connected mean

Golf — Sat, 18 Jul 2020 14:01:05 GMT

Hello FreelanceReinhard AMETHYS,
Thank You so much for very cool codes.
Bests,
Golf.