topic Re: proc gplot, proc sgplot and proc print, all on the same page in Graphics Programming

proc gplot, proc sgplot and proc print, all on the same page

zimcom — Tue, 14 Jul 2020 21:18:25 GMT

Hi all,

I have created a patient report, in which I used proc gplot (to draw a graph), proc sgplot (to draw another graph) and proc print (to print a listing) of one patient of interest through ODS. The graphs and listing came out fine, but are all on individual page, which is not good and efficient for the data cross checking.

Question for the community, is it possible to print all the graphs and listing output on one page for one patient? I used a marco to loop through the patient list to get every single patient data printed on one page for effective data review.

Thanks

Re: proc gplot, proc sgplot and proc print, all on the same page

PaigeMiller — Tue, 14 Jul 2020 21:31:47 GMT

Which ODS destination are you using?

Re: proc gplot, proc sgplot and proc print, all on the same page

ballardw — Tue, 14 Jul 2020 21:36:27 GMT

Ods Destination used? RTF and PDF have different approaches to some of the same appearance elements. A

ODS destination options in effect? These are likely what is creating one page per graph plus the proc print output.

Papersize or similar setting or default used to print your documents?

Size of the graph images? The physical size of graphs may prevent them from fitting on a single page. If your graphs are 5 inches tall and displaying in a document for 10 inch tall paper then margins + space between graphs+the graphs could exceed the space available.

Size/amount of the proc print output?

I would strongly consider whether you really need proc GPLOT output as that may complicate some of the possible solutions.

It may be possible to include the proc print output, depending on volume, in an INSET block of a graph.

I would suggest attaching an example of your output document as that likely will provide answers to many other questions that may need to be answered. And the code used to generate the output for one of these documents as well would likely be a good a idea.

Re: proc gplot, proc sgplot and proc print, all on the same page

zimcom — Tue, 14 Jul 2020 21:37:03 GMT

%macro loops;
%do i=1 %to &cnt;
data _null_;
set lst;
if _n_ = &i then call symput('sub',subject);
run;
%put ⊂
ods pdf file="C:\Users\Documents\plot_&sub..pdf" ;

goptions reset=all hsize=15cm vsize=10cm;
axis2 order=(0 to 6) minor=none;
symbol1 interpol=join width=2 color=vligb value=dot height=6;
symbol2 interpol=join width=2 color=salmon value=dot height=6;

proc gplot data=data1;
where subject = "&sub";
by SUBJECT;
plot a * b/ overlay vaxis=axis2;
run;

proc sgplot data=ae;
format aestdat date7.;
refline 0 / axis=x lineattrs=(color=black);
highlow y=aeseq low=aestdy high=aeendy / type=bar group=aesev
lineattrs=(color=black pattern=solid) barwidth=0.8
lowlabel=aedecod highcap=highcap attrid=Severity;
scatter y=aeseq x=aestdat / x2axis markerattrs=(size=0);
xaxis grid display=(nolabel) offsetmax=0.02;
x2axis display=(nolabel) offsetmax=0.02 ;
yaxis grid display=(noticks novalues nolabel);
where subject = "&sub";
by SUBJECT;
run;

proc print data=dm;
where subject = "&sub";
run;

ods pdf close;
quit;
%end;
%mend;
%loops;

Re: proc gplot, proc sgplot and proc print, all on the same page

PaigeMiller — Tue, 14 Jul 2020 21:46:56 GMT

As stated by @ballardw, there's only so much space on a page, and maybe your output doesn't fit. You can try reducing the margins to squeeze just a little more onto the page, or you can try reducing the size of your graphics and reducing the font size of your PROC PRINT output ... but really, there's only so much you can do before eitehr you are forced to use another page or the graphs and text become so small taht it isn't readable.

Re: proc gplot, proc sgplot and proc print, all on the same page

zimcom — Tue, 14 Jul 2020 21:48:04 GMT

I copied and pasted the code in above.
The two graphs are all the proper size and can easily fit into one page and the DM listing is only one row. If I don't print them all on one page, then it would defeat the purpose of this report.
I used proc GPLOT, because I find an example of code which draw the kind of graph I need.

Thanks

Re: proc gplot, proc sgplot and proc print, all on the same page

zimcom — Tue, 14 Jul 2020 21:54:22 GMT

I checked the output, the space is not the reason that pushed the 2nd graph onto the next page, the lisitng is only one row, so all of them should fit into one page if there is such a control.
Thanks

Re: proc gplot, proc sgplot and proc print, all on the same page

Reeza — Tue, 14 Jul 2020 22:01:56 GMT

Look at the STARTPAGE options for the ODS destination you're using. That option controls when a new page is started and you can explicitly control it.

Re: proc gplot, proc sgplot and proc print, all on the same page

ballardw — Tue, 14 Jul 2020 22:19:28 GMT

@zimcom wrote:
I checked the output, the space is not the reason that pushed the 2nd graph onto the next page, the lisitng is only one row, so all of them should fit into one page if there is such a control.
Thanks

SAS inserts vertical space between output so you may need to look closer.

But your example code shows nothing attempting to control spacing. The ODS PDF option STARTPAGE default setting is YES, which places each procedure's output on a separate page. You might try adding

STARTPAGE=NO to force all of the output to single page. But I still suspect you're going to have to play around with the size of the SGPLOT size. Personally I would move the GPLOT code to SGPLOT and then a single setting with ODS Graphics would set a similar height and width on the page.

If you are using the BY Subject to get the By line information as a label you might consider actually using Title statements, which you can control font size and the option GTITLE which makes the title part of the graphic output. I suspect that the space between the BY line and the graph may take up more space then you think.

Re: proc gplot, proc sgplot and proc print, all on the same page

Reeza — Tue, 14 Jul 2020 22:44:35 GMT

If you've never specified the STARTPAGE option the default is each new PROC outputs to a new page. Your code shows no use of the STARTPAGE option. For starters try setting it to never.

ods pdf file="C:\Users\Documents\plot_&sub..pdf" startpage=NEVER ;

https://support.sas.com/rnd/base/ods/odsprinter/PDF-tips.pdf

Re: proc gplot, proc sgplot and proc print, all on the same page

zimcom — Wed, 15 Jul 2020 13:48:17 GMT

@Reeza @ballardw @PaigeMiller

Thank you all, I can't express how much I appreciated your help on this!

Re: proc gplot, proc sgplot and proc print, all on the same page

zimcom — Wed, 15 Jul 2020 14:06:54 GMT

"the GPLOT code to SGPLOT and then a single setting with ODS Graphics would set a similar height and width on the page." This would be ideal, if I can make the two graphs consistent, but I can't find the equivalent code of SGPLOT to draw what I did by using GPLOT, and I am new to SAS graphics procedure.

Re: proc gplot, proc sgplot and proc print, all on the same page

DanH_sas — Wed, 15 Jul 2020 14:19:16 GMT

If you're asking about setting the size on an SG procedure output, use the ODS Graphics statement:

odd graphics / width=15cm height=10cm;

Think of this statement as similar to the GOPTIONS statement, from the perspective that global options for ODS Graphics can be controlled from this statement.

Re: proc gplot, proc sgplot and proc print, all on the same page

zimcom — Wed, 15 Jul 2020 14:29:51 GMT

That helps to make the graphs the same size and looks much better.

Can proc sgplot draw the same graph as proc gplot did in my case, if this is possible, then all the graph setting can only be set once, that is what I meant.

Re: proc gplot, proc sgplot and proc print, all on the same page

DanH_sas — Wed, 15 Jul 2020 15:13:18 GMT

If you're asking if your GPLOT example can be drawn using SGPLOT, the answer is yes. There code would look something like the following:

proc sgplot data=data1;
where subject = "&sub";
by SUBJECT;
yaxis values=(0 to 6);
series x=b y=a / markers lineattrs=(color=vligb thickness=2) markerattrs=(symbol=circlefilled size=6);
run;

Re: proc gplot, proc sgplot and proc print, all on the same page

DanH_sas — Wed, 15 Jul 2020 15:14:26 GMT

BTW, you do not need to use the BY statement, since you are using a WHERE clause.

Re: proc gplot, proc sgplot and proc print, all on the same page

Reeza — Wed, 15 Jul 2020 15:18:06 GMT

You don't include data but your GPLOT looks like just a basic SERIES plot? Have you tried a SERIES statement in SGPLOT?

Re: proc gplot, proc sgplot and proc print, all on the same page

zimcom — Wed, 15 Jul 2020 15:22:03 GMT

I use the by statement to show the Subject ID on the graph

Re: proc gplot, proc sgplot and proc print, all on the same page

zimcom — Wed, 15 Jul 2020 15:27:36 GMT

Thank you so much for your help! I really appreciated it!!