topic PROC SGPLOT: How to get consistent colors across BY groups? in Graphics Programming

PROC SGPLOT: How to get consistent colors across BY groups?

PaigeMiller — Mon, 13 Jul 2020 11:06:41 GMT

When I run this code, for the first BY group (Origin=Asia), the legend shows that SUV is represented by the red circle. In the second BY group (Origin=Europe), SUV is represented by the cyan color circle. How can I get consistent colors across BY groups, so that each group has the same color in each plot?

proc sort data=sashelp.cars out=cars;
	by origin;
run;
proc sgplot data=cars;
	styleattrs datacontrastcolors=(red green blue cyan magenta orange black);
	by origin;
	scatter x=msrp y=mpg_city/group=type;
run;

Re: PROC SGPLOT: How to get consistent colors across BY groups?

djrisks — Mon, 13 Jul 2020 11:27:34 GMT

Hello, you can use Discrete Attribute Maps to achieve the consistency between groups. This is because generally, the attributes for the group are determined by the order that the value is within the data. Using discrete attribute maps can make you indicate the colors that you want to assign to each group value.

There are more details here: https://documentation.sas.com/?docsetId=grstatproc&docsetTarget=n18szqcwir8q2nn10od9hhdh2ksj.htm&docsetVersion=9.4&locale=en

Here is an example:

proc sort data=sashelp.cars out=cars;
  by origin;
run;

data myattrmap;
  length markercolor $ 7 markersymbol $ 6;
  input id $ value $ markercolor $ markersymbol $;
datalines;
myid Hybrid red circle
myid SUV green circle
myid Sedan blue circle
myid Sports cyan circle
myid Truck magenta circle
myid Wagon orange circle 
;
run;

proc sgplot data=cars dattrmap=myattrmap;
  by origin;
  scatter x=msrp y=mpg_city/group=type attrid=myid;
run;

Re: PROC SGPLOT: How to get consistent colors across BY groups?

PaigeMiller — Mon, 13 Jul 2020 11:55:45 GMT

Thanks @djrisks. I think I should have thought of that.

Anyway, I discovered that when you do this on my real data, which uses custom formats, the value in the MYATTRMAP must be the formatted value, not the unformatted value.

Re: PROC SGPLOT: How to get consistent colors across BY groups?

djrisks — Mon, 13 Jul 2020 13:10:58 GMT

You're welcome @PaigeMiller . Yes, that's true about the formatted values.

Re: PROC SGPLOT: How to get consistent colors across BY groups?

Rick_SAS — Mon, 13 Jul 2020 16:57:54 GMT

For an introduction to discrete attribute maps, see the articles

"Roses are red, violets are blue" by Dan Heath

"Consistent groups colors by value" by Sanjay Matange

For advanced users, see "Automate the creation of a discrete attribute map" by Rick Wicklin