topic Re: How to get the subscript and superscript in proc sg plot. in Graphics Programming

How to get the subscript and superscript in proc sg plot.

Luna0571 — Tue, 07 Jul 2020 14:07:04 GMT

I have tried every solution from the community. I am using SAS EG.
Ex: text to be displayed in graph is ABx . I want to display x as subscript in proc sg plot waterfall model.

Re: How to get the subscript and superscript in proc sg plot.

ChrisHemedinger — Tue, 07 Jul 2020 14:58:17 GMT

You want to display this in the axis label or in a data label? ODS allows for Unicode characters, including super/subscripts.

/* Define sample data for the plot */
data sample;
   do x=1 to 10; 
      y=int(ranuni(0)*100);
      output;
   end;
run;
/* Define the ODS escape character */
ods escapechar='^';

/* Define the attributes of the image file */
ods graphics / reset width=600px height=400px ;

title 'Using Subscripts and Superscripts';

proc sgplot data=sample;
   scatter x=x y=y / markerattrs=(symbol=circlefilled color=blue);

   /* Specify the 4-digit hex value for the subscript 2 and superscript 2 */
   xaxis label="H^{unicode '2082'x}O^{unicode '00b2'x}";
   /* Specify the 4-digit hex value for the superscript 2 and subscript 2 */
   yaxis label="N^{unicode '00b2'x}H^{unicode '2082'x}";
run;

Re: How to get the subscript and superscript in proc sg plot.

Luna0571 — Tue, 07 Jul 2020 15:54:21 GMT

Thanks Chris. But I want to display in footnote. In my example ABx is a text in one column. Wherever ABx comes into picture x should be subscript of AB.

Re: How to get the subscript and superscript in proc sg plot.

ChrisHemedinger — Tue, 07 Jul 2020 16:12:57 GMT

A footnote in the graph, like an inset?

   inset "Inset footnote for AB^{sub '2'} " 
         / textattrs=(size=12pt) position=bottomleft;

Re: How to get the subscript and superscript in proc sg plot.

JeffMeyers — Tue, 07 Jul 2020 16:13:28 GMT

Can you post your actual SGPLOT code? No need for data but just want to see how many places you're talking about needing a subscript (different places need different methods).

Re: How to get the subscript and superscript in proc sg plot.

Luna0571 — Tue, 07 Jul 2020 16:21:28 GMT

Hi Jeff.
Let me keep it simple.I have a text variable the values are A,B,C,D for A,B I wanna display superscript & subscript for C,D respectively.

Re: How to get the subscript and superscript in proc sg plot.

DanH_sas — Tue, 07 Jul 2020 16:49:51 GMT

Here you go:

ods escapechar="~";
footnote f="Monotype Sans WT J" "This is an AB~{unicode '2093'x}";
proc sgplot data=sashelp.class;
scatter x=weight y=height;
run;

This key is choosing the correct font. The "2093' glyph is not available in every font -- only in the more "full-featured" fonts. If you are using san-serif fonts in your output, the font in the programs should work well for you.

Hope this helps!

Dan

Re: How to get the subscript and superscript in proc sg plot.

JeffMeyers — Tue, 07 Jul 2020 17:35:51 GMT

If you want to show super or subscripts in SGPLOT graph statements (TEXT, VBAR, etc.) then you need to find them in Unicode form (I think DAN found one for subscript x). They still don't support direct super or subscripts in SGPLOT unfortunately. If you can find the character you want though in Unicode form then you can use the following method to get the values into a graph statement:

https://blogs.sas.com/content/sgf/2015/09/18/specifying-unicode-values-and-colors-is-easier-with-the-proc-sgplot-and-gtl/

Basically instead of having character values that include the escape character and Unicode value you need to make a formatted variable where the format contains the escape character and Unicode value. It's an extra step I feel should be removed at some point by SAS but for now that is how it works.

Re: How to get the subscript and superscript in proc sg plot.

DanH_sas — Tue, 07 Jul 2020 17:41:11 GMT

We do currently support sup/sub in INSET statements in SGPLOT (as @ChrisHemedinger demonstrated); but, in other string situations (title, footnote, axis labels, legend labels, etc.), you must use a Unicode character to get sup/sub.

Re: How to get the subscript and superscript in proc sg plot.

kivester — Wed, 13 Aug 2025 16:52:38 GMT

I apologize for jumping into a thread, but is there a way to get a subscript capital L?

Re: How to get the subscript and superscript in proc sg plot.

Ksharp — Thu, 14 Aug 2025 01:04:17 GMT

%let label1=XAXIS Label(*ESC*){sub 'L'}  ;
%let label2=YAXIS Label(*ESC*){sup 'L'} ;
data _anno;
length label $ 200;
 drawspace="layoutpercent"; function="text"; textweight="normal"; textsize=12;textcolor="black"; width=200;
 x1=50; y1=2.5;label="&label1."; output;
 x1=2.5;  y1=50;rotate=90;label="&label2."; output;
 run;
proc sgplot data=sashelp.class sganno=_anno;   
scatter x=weight y=height;   
xaxis label=' ';
yaxis label=' ';
run;