topic Re: How do I name a JPEG export of a PROC GMAP? in Graphics Programming

How do I name a JPEG export of a PROC GMAP?

young_spruce — Tue, 24 Mar 2020 09:06:36 GMT

I'm trying to output my PROC GMAP results as a JPEG to put into a presentation. I found an earlier topic and used that code. However, that topic doesn't specify how to edit the name of the resulting JPEG file. Since I need to output a lot of maps, I would like to give each JPEG a name other than "GMAPnn", to make it easier to identify.

1. How do can edit the name of the JPEG file?

2. How do I make that name dynamic to use in a macro?

FILENAME plots "&OUTPATH";
goptions reset=all 
DEVICE=jpeg 
xpixels=1200
ypixels=1000
transparency 
GSFNAME=plots 
GSFMODE=REPLACE 
NOFILEONLY;
ods _all_ close;
ods listing;

proc gmap map=map data=data;
id ID1;
choro DATA1/
cdefault=gold
coutline=white
legend=legend1;
legend1 value=(h=1 f=arial) label=(h=1 f=arial 'DATA1');
run;
quit;
ods listing close;

Re: How do I name a JPEG export of a PROC GMAP?

Kurt_Bremser — Tue, 24 Mar 2020 09:19:15 GMT

Switch to using PROC SGMAP, then you can make use of ODS features.

Re: How do I name a JPEG export of a PROC GMAP?

young_spruce — Tue, 24 Mar 2020 10:45:57 GMT

Hi Kurt,

Thanks for the quick reply. I'm very unfamiliar with SGMAPS and can't quite figure out how to reproduce the map I created using the GMAP procedure.

Could you help me translate the code below into the SGMAP procedure? I'm having trouble defining colors, using the legend and subsetting the data.

pattern1 value=solid color='CXeff3ff'; 
pattern2 value=solid color='CXbdd7e7';
pattern3 value=solid color='CX6baed6'; 
pattern4 value=solid color='CX3182bd'; 
pattern5 value=solid color='CX08519c'; 

proc gmap map=map data=data;
id ID1;
choro DATA1/
cdefault=white
coutline=white
legend=legend1;
legend1 value=(h=1 f=arial) label=(h=1 f=arial 'DATA1');
where ID2="VALUE";
run;
quit;

Re: How do I name a JPEG export of a PROC GMAP?

DanH_sas — Tue, 24 Mar 2020 17:52:27 GMT

I think the NAME option on the CHORO statement will do what you need.

Hope this helps!

Dan

Re: How do I name a JPEG export of a PROC GMAP?

Ksharp — Wed, 25 Mar 2020 12:06:06 GMT

Calling @GraphGuy

Re: How do I name a JPEG export of a PROC GMAP?

GraphGuy — Thu, 02 Apr 2020 12:19:56 GMT

Generally, with Proc Gmap, you can use the name= option on the choro statement to control the name of the gseg, and then the name of the gseg is used as the name of the png (or jpeg) image file. The syntax you're using is a bit 'old' ... I would recommend this newer syntax (and I also recommend using png output, rather than jpeg). The following code saves the output as the name 'mymap.png'.

%let name=mymap;

filename odsout '.';

goptions device=png;

ODS LISTING CLOSE;
ODS HTML path=odsout body="&name..htm" style=htmlblue;

proc gmap map=mapsgfk.us data=mapsgfk.us;
id state;
choro segment / levels=1 nolegend name="&name";
run;

quit;
ODS HTML CLOSE;
ODS LISTING;

Re: How do I name a JPEG export of a PROC GMAP?

young_spruce — Wed, 22 Apr 2020 12:23:09 GMT

Sorry for the delayed response. Using the name option solved my problem and using your code worked perfectly. Thanks a lot for the help.