topic How do I change the CLM colors for LOESS SGPLOT grouped data, with unique colors for each group? in Graphics Programming

How do I change the CLM colors for LOESS SGPLOT grouped data, with unique colors for each group?

bchronister — Tue, 11 Feb 2020 18:55:29 GMT

Hello,

I have data that I am creating a Loess graph, that is categorized into two groups by cortisol median. I am trying to change the CLM colors from the default red and blue, and want them to match the color of the trendline and data points. I have identified how to change the CLM colors to the same color, but am not sure how to make them two different colors. Can anyone help?

This is the code:

ods graphics on / width=6in;
ods graphics on / height=6in;


proc sgplot data=loess_data_ln aspect=1;
 Where rankcategory=175 & depanx=1  & hormone=1 & gender=0;
 LOESS Y=meanscore X=hormonemean_ln /group=cortisolmedian smooth=0.9 alpha=0.05  CLMattrs=(CLMFILLATTRS=(color=pink transparency=0.35)) degree=1 clm; 
 XAXIS grid label ="Testosterone, pg/mL" LABELATTRS=(family=arial size=12)min=2 max=5 valueattrs=(family=arial size=12pt) ; 
 YAXIS grid label="CDI-2 Mean Score" LABELATTRS=(family=arial size=12 ) valueattrs=( family=arial size=12pt) max=90  ;
 styleattrs datacontrastcolors=(VLIGB VIGB) datalinepatterns=(1)
 			datasymbols=(circlefilled) ;
 keylegend/ title=" " valueattrs=( family=arial size=12pt) ;
 format cortisolmedian cortisolmedianfmt. depanx depanxfmt. hormone hormonefmt.;
 title " " ;
	
run;

Re: How do I change the CLM colors for LOESS SGPLOT grouped data, with unique colors for each group?

Rick_SAS — Tue, 11 Feb 2020 19:26:34 GMT

use the DATACOLOR= option on the STYLEATTRS statement:

proc sgplot data=sashelp.iris;
 Where species in ("Setosa", "Virginica");
 styleattrs datacontrastcolors=(VLIGB VIGB)
            datacolors=(VLIG VIB) ;
 LOESS Y=SepalLength X=SepalWidth /group=Species smooth=0.9 alpha=0.05  
       CLMattrs=(CLMFILLATTRS=(transparency=0.35)) degree=1 clm; 
 XAXIS grid; 
 YAXIS grid;
run;

Re: How do I change the CLM colors for LOESS SGPLOT grouped data, with unique colors for each group?

bchronister — Tue, 11 Feb 2020 19:40:50 GMT

That worked, thank you!