topic Re: round in displaystats in Graphics Programming

round in displaystats

Muandre — Fri, 07 Feb 2020 09:49:49 GMT

Hi,

I want to round mean and median, I use proc template to produce my boxplot. Is this possible?

proc template;

define statgraph test1;

begingraph;

layout overlay;

boxplot x=sex

y=weight

displaystats=(n mean median)

;

endlayout;

endgraph;

end;

run;

proc sgrender data=sashelp.class template=test1;

run;

Re: round in displaystats

BrunoMueller — Fri, 07 Feb 2020 15:15:44 GMT

Just use the FORMAT statement in your Proc SGRENDER. This will also work with Proc SGPLOT.

See example code below

proc sgplot data=sashelp.class;
  vbox weight / 
    category=sex  DISPLAYSTATS=(n mean median)
  ;
  format weight comma10.5;
run;

ods path
  (prepend) work.templates (update)
;

proc template;
  define statgraph test1;
    begingraph;
      layout overlay;
        boxplot x=sex
          y=weight
          /
          displaystats=(n mean median)
        ;
      endlayout;
    endgraph;
  end;
run;

proc sgrender data=sashelp.class template=test1;
  format weight comma10.3;
run;

Re: round in displaystats

Muandre — Fri, 14 Feb 2020 07:44:19 GMT

Perfect! Thank you!