SGPanel: How to put the header in each graph instead of on top of each graph?

jjjch — Wed, 28 Aug 2019 17:52:23 GMT

This is what I created:

And below is what I wanted:

How to implement it? Thank you! Below are my codes:

%macro randomNormal(mean=0, stddev=1, N=100, outDS=);
	data &outDS.(keep=x);
		call streaminit(datetime());
		do i = 1 to &N;
			x = rand("NORMAL", &mean, &stddev);
			output;
		end;
	run;
%mend;

%randomNormal(mean=100, stddev=10, N=100, outDS=One);
%randomNormal(mean=15, stddev=10, N=100, outDS=Two);

data myData;
	set One(in=in1) Two(in=in2);
	if in1 then Name='One';
	if in2 then Name='Two';
run;

proc sgpanel data=myData;
panelby Name / columns=1;
histogram x / binwidth=1;
run;

Re: SGPanel: How to put the header in each graph instead of on top of each graph?

DanH_sas — Wed, 28 Aug 2019 20:09:58 GMT

You can do it like this:

proc sgpanel data=myData;
panelby Name / columns=1 noheader;
histogram x / binwidth=1;
inset name / textattrs=(color=red size=14pt) separator='=';
run;

topic Re: SGPanel: How to put the header in each graph instead of on top of each graph? in Graphics Programming

SGPanel: How to put the header in each graph instead of on top of each graph?

Re: SGPanel: How to put the header in each graph instead of on top of each graph?