topic Can i draw a plot for multiple linear regression? in Graphics Programming

Can i draw a plot for multiple linear regression?

jeminjeon — Sat, 27 Jul 2019 10:46:51 GMT

Dear All,

is that possible to make a graph(plot) for a multiple linear regression model with several covariates? I'd like to make a plot after adjustment several covariates. I saw the plot of model y=x, which adjusted covariates but don't know how to make it by sas. Anyone can provided me some idea or example??

Here is my code. Don't know which option i have to add.

proc reg data=aa;

model change_weight= sex age region alcohol toe_hg;

run;quit;

I want to make a plot of model (change_weight=toe_hg) adjusted covariates (sex, age, region).

Thanks a lot

Re: Can i draw a plot for multiple linear regression?

Rick_SAS — Sat, 27 Jul 2019 10:15:58 GMT

SAS regression procedures such as PROC REG and PROC GLM create many plots automatically when you use

ODS GRAPHICS ON;

to turn on ods graphics. For examples, see the Getting Started examples in PROC REG.

You can control the type of graphs by using the PLOTS= option on the PROC statement.

Re: Can i draw a plot for multiple linear regression?

PaigeMiller — Sat, 27 Jul 2019 10:50:16 GMT

In practicality, you cannot create a plot of your multiple linear regression because such a plot would have to show a surface in six dimensions, and not even SAS can produce such a six-dimensional plot. However, SAS does produce a lot of plots that can help you diagnose if the fit is a good fit or not, and produce other diagnostics as well, as explained by @Rick_SAS by using the PLOTS= option.

Re: Can i draw a plot for multiple linear regression?

PGStats — Sun, 28 Jul 2019 03:42:32 GMT

One idea would be to create a lattice panel of graphs (using proc sgpanel) with sex as columns and regions as rows. On each graph you could show the data for a given sex and region and some fitted lines for a few select ages.

Re: Can i draw a plot for multiple linear regression?

PGStats — Sun, 28 Jul 2019 04:34:47 GMT

Here is an example using the sashelp.heart dataset:

/* (Poor) model for predicting cholesterol */
proc glm data=sashelp.heart;
class sex smoking_status;
model cholesterol = sex ageAtStart smoking_status|weight;
store test;
run;

/* Values at which to get predictions */
data cholValues;
do sex = "Female", "Male";
    do smoking_status = "Very Heavy (> 25)", "Non-smoker", "Light (1-5)", "Moderate (6-15)", 
        "Heavy (16-25)";
        do ageAtStart = 30 to 75 by 15;
            do weight = 120 to 240 by 20;
                output;
                end;
            end;
        end;
    end;
run;
            
/* Generate the predictions */
proc plm restore=test;
score data=cholValues out=cholPred predicted=predCholesterol;
run;

/* Assemble observations and predictions in single dataset */
data cholGraph;
set sashelp.heart cholPred(rename=ageAtStart=age);
run;

proc sort data=cholGraph; by sex smoking_status age weight; run;

/* Create graph */
ods graphics / width=600 height = 1000;
proc sgpanel data=cholGraph ;
panelby sex smoking_status / layout=lattice onepanel novarname;
scatter x=weight y=cholesterol;
series x=weight y=predCholesterol / group=age  nomissinggroup 
    lineattrs=(pattern=solid);
run;

Re: Can i draw a plot for multiple linear regression?

Rick_SAS — Sun, 28 Jul 2019 10:39:55 GMT

You can also use the EFFECTPLOT statement to visualize regression models.

The article shows how to use the EFFECTPLOT statement directly in regression procedures and how to use the STORE statement and PROC PLM to visualize the model in a post-fit analysis.