topic How do I rotate the bar values in proc SGPLOT in Graphics Programming

How do I rotate the bar values in proc SGPLOT

mft — Tue, 05 Feb 2019 15:32:34 GMT

Hi there,

I am trying to produce a graph like the one below. That is not my graph but just for reference. In the graph below, the bar values are rotated vertically, I am trying to rotate my values at an angle. I read somewhere that the values will be automatically rotated to a vertical position when the values don't fit in the space, however I need to have my values rotated even though I only have 5 digits number ( for example 45,000).

This is the code I am using and I am using SAS 9.4:

proc sgplot data=table1 noborder;
where label='Avg Size' and state=10;
format ld1 comma.;
vbar year/ response=ld1 datalabel datalabelattrs=(size=12)
barwidth =0.2
dataskin=gloss
baselineattrs=(thickness=0)
fillattrs=(color=green);
xaxis display=(nolabel noticks) ;
yaxis display=none ;
run;

Re: How do I rotate the bar values in proc SGPLOT

PeterClemmensen — Tue, 05 Feb 2019 15:59:51 GMT

Hi and welcome to the SAS communities 🙂

You can use

datalabelfitpolicy=rotate

in the VBAR Statement Options.

Re: How do I rotate the bar values in proc SGPLOT

DanH_sas — Tue, 05 Feb 2019 16:04:31 GMT

We currently do not have a ROTATEALWAYS option for DATALABELFITPOLICY; however, if the values are close to the edge of the bars, you can make the rotation kick in by shrinking the BARWIDTH a little more.

Hope this helps!

Dan

Re: How do I rotate the bar values in proc SGPLOT

PeterClemmensen — Tue, 05 Feb 2019 16:07:00 GMT

I just learned something. I thought the DATALABELFITPOLICY=ROTATE would rotate the data label values no matter what.

@DanH_sas thank you for clarifying. Will we see a ROTATEALWAYS Option for DATALABELFITPOLICY in a future release?

Re: How do I rotate the bar values in proc SGPLOT

DanH_sas — Tue, 05 Feb 2019 16:17:12 GMT

We'll see what we can do 🙂

Thanks!
Dan

Re: How do I rotate the bar values in proc SGPLOT

mft — Tue, 05 Feb 2019 16:54:32 GMT

Thank you for this information!

Re: How do I rotate the bar values in proc SGPLOT

Ksharp — Wed, 06 Feb 2019 14:13:11 GMT

How about this one ?

proc summary data=sashelp.class nway;
class age sex;
var height;
output out=temp sum=;
run;
data temp;
 set temp;
 if sex='M' then h1=height;
  else h2=height;
run;

proc sgplot data=temp;
vbarparm category=age response=height  /group=sex groupdisplay=cluster ;
text x=age y=h1 text=h1/ discreteoffset=0.2 rotate=90 strip;
text x=age y=h2 text=h2/ discreteoffset=-0.2 rotate=90 strip;
run;

Re: How do I rotate the bar values in proc SGPLOT

Jay54 — Wed, 06 Feb 2019 14:44:48 GMT

This should work. I am thinking you can use TEXT statement with GROUP and GROUPDISPLAY=Cluster to match the VBARPARM. This will make it more scale-able to different group levels.

Re: How do I rotate the bar values in proc SGPLOT

Ksharp — Wed, 06 Feb 2019 14:55:52 GMT

Thanks. As you said.

proc summary data=sashelp.class nway;
class age sex;
var height;
output out=temp sum=;
run;


proc sgplot data=temp;
vbarparm category=age response=height  /group=sex groupdisplay=cluster ;
text x=age y=height text=height/group=sex groupdisplay=cluster rotate=90 strip;
run;