topic Re: PROC SGPLOT Default Colour in Graphics Programming

PROC SGPLOT Default Colour

Naviava1973 — Tue, 15 Jan 2019 10:06:58 GMT

Hello SAS community. I have written a PROC SGPLOT code that includes the BLOCK statement generating beautiful graphs. I need to identify the default colors used but confused by the several HLS/RGB/HSV options. I used the default template i.e HTMLBlue. I was wondering if someone can point me to some useful way of identifying the precise colors presented in each block. My code is:

PROC SGPLOT DATA = Labs;
BLOCK X = age_weeks BLOCK = PHASES /TRANSPARENCY=0.8 POSITION=CENTER VALUEFITPOLICY=/*NONE | SHRINK |SPLIT*/ SPLIT SPLITCHAR='';
SERIES X = age_weeks Y = cd4_percent / MARKERS MARKERATTRS=(COLOR=BLACK SYMBOL=CIRCLE) LINEATTRS = (COLOR=RED THICKNESS = 2 PATTERN=DASH) LEGENDLABEL = 'CD4 Percent';
XAXIS LABEL = 'Weeks';
YAXIS MIN=30 LABEL = 'CD4 Percent values';
RUN;

Re: PROC SGPLOT Default Colour

PeterClemmensen — Tue, 15 Jan 2019 11:43:17 GMT

You can do like this

libname temp "C:/temp";
proc template;
source styles.statistical / file='temp.tmp'; /* write template to text file */
quit;
 
data Colors;
keep Name Color R G B;
length Name Color $8;
infile 'temp.tmp';
input;
k = find(_infile_,'gdata','i');/* EDIT: Use gdata instead of gcdata */
if k > 0 then do;
   s = substr(_infile_, k);
   j = index(s, "'");
   Name = substr(s, 1, j-1);
   j = index(s, "=");
   Color = compress(substr(s, j+1));
   R = inputn(substr(Color, 3, 2), "HEX2.");
   G = inputn(substr(Color, 5, 2), "HEX2.");
   B = inputn(substr(Color, 7, 2), "HEX2.");
end;
if k > 0;
run;
 
proc print data=Colors; 
var Name Color R G B;
run;

The approach is from What colors does PROC SGPLOT use for markers?. I edited the code a little bit and commented the main change: looking for gdata instead of gcdata in the template file. In the Colors data set, gdata1 is the first color used, gdata2 is number two and so on.

Re: PROC SGPLOT Default Colour

Naviava1973 — Tue, 15 Jan 2019 12:42:55 GMT

Thank you very much Draycut. This is helpful.

Re: PROC SGPLOT Default Colour

PeterClemmensen — Tue, 15 Jan 2019 16:02:42 GMT

I'm glad to hear that 🙂 Please let me know if I can help you with anything else. Otherwise, please mark this thread as a solution.