topic Re: how do I set range for scatter plot in proc template in Graphics Programming

how do I set range for scatter plot in proc template

xiangpang — Tue, 04 Dec 2018 03:12:01 GMT

hi,

Anyone know how to set range for scatter plot in proc template?

I want to make two scatter plot side by side in proc template, with same x range and y range. how to do it?

Thanks

proc template;   
define statgraph scatter;      
layout gridded / columns=2 row=1;             
layout overlay;             
        scatterplot x=height1 y=weight1;            
endlayout;        
layout overlay;             
       scatterplot x=height2 y=weight2;             
endlayout  ;      
endlayout;   
end; 
run;

Re: how do I set range for scatter plot in proc template

Reeza — Tue, 04 Dec 2018 05:32:05 GMT

Set xaxisopts and yaxisopts.

See example below which is for a survival curve.

https://support.sas.com/documentation/cdl/en/statug/63962/HTML/default/viewer.htm#statug_templt_a0000000061.htm

layout overlay / xaxisopts=(shortlabel=XNAME offsetmin=.05
   linearopts=(viewmax=MAXTIME tickvaluelist=XTICKVALS
   tickvaluefitpolicy=XTICKVALFITPOL)) yaxisopts=(label=
   "Survival Probability" shortlabel="Survival" linearopts=(viewmin=
   0 viewmax=1 tickvaluelist=(0 .2 .4 .6 .8 1.0)));

Re: how do I set range for scatter plot in proc template

DanH_sas — Tue, 04 Dec 2018 15:40:46 GMT

You'll want to use a LAYOUT LATTICE instead of a LAYOUT GRIDDED, and you will want to set the COLUMNDATARANGE and ROWDATARANGE to UNIONALL so that the data ranges from all cells are included in the axis range. Here is a simple example:

proc template;
define statgraph scatter;
begingraph;
layout lattice / columns=2 rows=1 columndatarange=unionall rowdatarange=unionall;
layout overlay;
        scatterplot x=height1 y=weight1;
endlayout;
layout overlay;
       scatterplot x=height2 y=weight2;
endlayout  ;
endlayout;
endgraph;
end;
run;

data class;
set sashelp.class;
height1 =height;
weight1=weight;
height2=height*2;
weight2=weight*2;
run;

proc sgrender data=class template=scatter; run;

Hope this helps!

Dan

Re: how do I set range for scatter plot in proc template

xiangpang — Fri, 07 Dec 2018 01:16:29 GMT

thanks for your help

Re: how do I set range for scatter plot in proc template

xiangpang — Fri, 07 Dec 2018 01:16:51 GMT

Thanks, that helps