topic Re: How to program the colors of your pie chart? in Graphics Programming

How to program the colors of your pie chart?

leonoramillan — Sun, 18 Nov 2018 16:08:22 GMT

Hey guys

I am trying to do a Pie figure with SAS on demand.

How do I get a pie with the right color? I mean, a pie showing the green, when the color of my category variable is green, red when the color is red, etc. I have tried the code below, but it doesn´t work.

Thank you in advance for your help 🙂

/*Pie chart*/

Data mydata;

Input Color $ Quantity;

Datalines;

Red 10

Yellow 40

Green 50

;

run;

title1'colors of my pie';

pattern1 color=red;

pattern2 color=yellow;

pattern3 color=green;

title1 'My pie';

proc gchart data=mydata;

pie color/ type=sum sumvar=Quantity noheader slice=outside value=inside;

run;

Re: How to program the colors of your pie chart?

SASKiwi — Sun, 18 Nov 2018 19:30:54 GMT

Try adding this:

goptions colors=(red yellow green);

Re: How to program the colors of your pie chart?

leonoramillan — Sun, 18 Nov 2018 19:59:06 GMT

Thank you SASKiwi. I tried both

goptions colors=(red yellow green);

And

goptions colors=(green yellow yellow);

The first option shows the red, yellow and green colors, but not in the desired match. The second one matched the colors. BUT, how can I program (ex-ante) a specific observation of the category with a color? Options colors=( ) seems to work randomly?

Re: How to program the colors of your pie chart?

SASKiwi — Sun, 18 Nov 2018 20:15:19 GMT

OK, I think I've got it now. Pattern1 sets the fill, the colors then cycle through the 3 available.

goptions colors=(red yellow green);
pattern1 value = solid;

Re: How to program the colors of your pie chart?

leonoramillan — Sun, 18 Nov 2018 20:25:04 GMT

I got this:

Re: How to program the colors of your pie chart?

SASKiwi — Sun, 18 Nov 2018 20:50:04 GMT

This gets the order right for me:

Data mydata;
Input Color $ Quantity;
Datalines;
Red 10
Yellow 40
Green 50
;
run;
  
title1'colors of my pie';
goptions colors=(red yellow green);
pattern1 value = solid;
 
title1 'My pie';
proc gchart data=mydata;
pie color/ type=sum sumvar=Quantity noheader slice=outside value=inside
          midpoints = 'Red' 'Yellow' 'Green';
run;

Re: How to program the colors of your pie chart?

SASKiwi — Sun, 18 Nov 2018 20:59:16 GMT

The full answer is the slices print in alphabetic order regardless of your colour list. The MIDPOINTS option changes the slice order to match the colour order you want.

Re: How to program the colors of your pie chart?

leonoramillan — Sun, 18 Nov 2018 20:59:17 GMT

Thank you very much SASKiwi. It worked 👌

Re: How to program the colors of your pie chart?

GraphGuy — Tue, 20 Nov 2018 12:59:39 GMT

Here's a slightly different way of doing it - changing the order of the colors in the pattern statements, to match the alphabetical order of the colors (or whatever variable you're using for the slices).

goptions xpixels=500 ypixels=500;
goptions htitle=14pt htext=11pt ftext='albany amt/bold';

Data mydata;
Input Color $ Quantity;
Datalines;
Red 10
Yellow 40
Green 50
;
run;

title1'colors of my pie';
pattern1 color=green;
pattern2 color=red;
pattern3 color=yellow;

title1 'My pie';
proc gchart data=mydata;
pie color/ type=sum sumvar=Quantity noheader slice=outside value=inside;
run;