topic How to change values on the axis line in a bar chart? in Graphics Programming

How to change values on the axis line in a bar chart?

aczech2001 — Wed, 24 Oct 2018 13:33:57 GMT

Hi to all,

I need to change values of the 'cause' from the axis values from 1,2,3,4,5 to 1=Trauma, 2= Vascular with Diabetes, 3= Vascular without diabetes', 4=Oncologic. Ideally, I would like to also assign the right gender to the columns (1=male, 2=female, for the Gender variable).

This is the code that I have so far:

ods graphics / reset width=6.4in height=4.8in imagemap;

proc sgplot data=MEDSTUD.STRIDE_T;
vbar Cause / group=Gender groupdisplay=cluster fillattrs=(transparency=0.75)
datalabel stat=percent;
yaxis grid;
run;

ods graphics / reset;

Please, could you highlight in your answer the changes?

I attach the data set in the attachments.

Would you keep the same code to rename of the values in the same way, if you were to produce the table of frequencies? if not, please, could you post an example as well?

Thank you again for everyone's support!

Best regards,

Agnieszka (a complete newbie to SAS)

Re: How to change values on the axis line in a bar chart?

Ksharp — Wed, 24 Oct 2018 13:42:39 GMT

1) make a format and format it :

proc format;

value fmt

1='Trauma'

2=' Vascular'

.........;

run;

proc sgplot.......

.......

format Cause fmt.;

run;

2) using values=() option:

proc sgplot data=MEDSTUD.STRIDE_T;
vbar Cause / group=Gender groupdisplay=cluster fillattrs=(transparency=0.75)
datalabel stat=percent;
xaxis values=('Trauma' 'Vascular ' ..............);
run;

Re: How to change values on the axis line in a bar chart?

GraphGuy — Mon, 12 Nov 2018 13:16:48 GMT

Here's a little more complete code, in case you need it, followed by the sample output:

proc import out=stride_t datafile='u:\Socket18Data.xlsx' dbms=xlsx;
run;

proc format;
value gen_fmt
1="Male"
2="Female"
;
value causefmt
1="Trauma"
2="Vascular with Diabetes"
3="Vascular without Diabetes"
4="Oncologic"
;
run;

ods graphics / reset width=6.4in height=4.8in imagemap;

proc sgplot data=STRIDE_T;
format gender gen_fmt.;
format cause causefmt.;
vbar Cause / group=Gender groupdisplay=cluster fillattrs=(transparency=0.75)
datalabel stat=percent;
yaxis grid;
run;

ods graphics / reset;