topic Re: Ods Excel proc report and 2 proc gchart in Graphics Programming

Ods Excel proc report and 2 proc gchart

mansour_ib_sas — Fri, 19 Oct 2018 11:00:21 GMT

Hello,

on the same excel page, below the proc report, I want to insert two graphs in two columns.

I miss an option like columns = 2 for this two graphs.

Could you help me please.

data men(rename=(name=name_m age=age_m sex=sex_m Weight=Weight_m height=height_m));

do i=1 to 10;
set sashelp.class(where=(sex='M'));
i=i;
output;
end;

run;

data women(rename=(name=name_f age=age_f sex=sex_f Weight=Weight_f height=height_f));
do i=1 to 10;
set sashelp.class(where=(sex='F') );
i=i;
output;
end;
run;

data reg;
merge  men women;by i;
col_vide='';
run;


ods _all_ close;

ods excel file="H:\Report.xlsx" options(sheet_interval="none");
proc report data =reg;
col('Men' name_m age_m sex_m Weight_m height_m) col_vide
('Women' name_f age_f sex_f Weight_f height_f);

run;


goptions device=png ;

proc gchart data=reg;
   vbar age_m ;
run; quit;

proc gchart data=reg;
   vbar age_f ;
run; quit;


ods excel close;

ODS LISTING CLOSE;

Re: Ods Excel proc report and 2 proc gchart

RW9 — Fri, 19 Oct 2018 12:32:31 GMT

Stop using the ancient gplot functions. Look at modern programming functions like sgplot, or in your case: sgpanel:

http://support.sas.com/documentation/cdl/en/grstatproc/62603/HTML/default/viewer.htm#sgpanel-concepts.htm

Re: Ods Excel proc report and 2 proc gchart

mansour_ib_sas — Fri, 19 Oct 2018 14:18:14 GMT

thank you for your answer,

ideally I try to do like this.

can we set the columns option at the beginning?

ods _all_ close;

ods excel file="H:\Report3.xlsx" options(sheet_interval="none");

proc report data =reg;
col('Men' name_m age_m sex_m Weight_m height_m) col_vide
('Women' name_f age_f sex_f Weight_f height_f);

run;


proc sgpanel data= reg;
panelby  sex_f /columns=1;

vbar age_f;


panelby  sex_m /columns=2 ;
vbar age_m;

run;
ods excel close;

Re: Ods Excel proc report and 2 proc gchart

RW9 — Fri, 19 Oct 2018 14:32:42 GMT

I am sorry, I do not understand what you mean. You set parameters where they are expected?

Re: Ods Excel proc report and 2 proc gchart

Jay54 — Fri, 19 Oct 2018 14:34:51 GMT

You can only have one PANELBY in one procedure step. It will automatically produce the number of cells needed based on the number of unique class values. Please review the doc for PROC SGPANEL, or see many examples here: https://blogs.sas.com/content/graphicallyspeaking/?s=sgpanel

Re: Ods Excel proc report and 2 proc gchart

mansour_ib_sas — Fri, 19 Oct 2018 15:01:22 GMT

Error Log:

ERROR: The same category variable must be used for summarized plots.




data men(rename=(name=name_m age=age_m sex=sex_m Weight=Weight_m height=height_m));

do i=1 to 10;
set sashelp.class(where=(sex='M'));
i=i;
output;
end;

run;

data women(rename=(name=name_f age=age_f sex=sex_f Weight=Weight_f height=height_f));
do i=1 to 10;
set sashelp.class(where=(sex='F') );
i=i;
output;
end;
run;

data reg;
merge  men women;by i;
col_vide='';
run;


ods _all_ close;

ods excel file="H:\Report3.xlsx" options(sheet_interval="none");

proc report data =reg;
col('Men' name_m age_m sex_m Weight_m height_m) col_vide
('Women' name_f age_f sex_f Weight_f height_f);

run;


proc sgpanel data= reg;
panelby  sex_f sex_m/columns=2;
  title "Yearly Sales by Product";
  vbar age_f;

  title "Yearly Sales by Product";
  vbar age_m;
  
run;

ods excel close;

Re: Ods Excel proc report and 2 proc gchart

DanH_sas — Fri, 19 Oct 2018 15:06:43 GMT

Your SGPANEL code should look like this:

title "Yearly Sales by Product";
proc sgpanel data= sashelp.class;
panelby  sex / columns=2 novarname;
  vbar age;
run;

Re: Ods Excel proc report and 2 proc gchart

Reeza — Fri, 19 Oct 2018 15:12:24 GMT

You need to reconsider your data structure for this graph.

Try this:

proc sort data=sashelp.class out=class; by sex;
run;
proc sgpanel data=class ;
panelby  sex /columns=2;
vbar age;
run;

I suspect you could also do that for PROC REPORT and not have to split up your data but I'm not 100% sure of that.

Re: Ods Excel proc report and 2 proc gchart

mansour_ib_sas — Fri, 19 Oct 2018 15:23:25 GMT

I thought about this option.

I consider that the subject is closed

Re: Ods Excel proc report and 2 proc gchart

mansour_ib_sas — Fri, 19 Oct 2018 15:24:22 GMT

Thank you