topic Re: Series plot CURVELABEL overlapping in Graphics Programming

Series plot CURVELABEL overlapping

hsaul — Fri, 03 Aug 2018 22:23:07 GMT

I am attempting to create a patient profile plot with four panels using PROC SGPANEL. The fourth panel consists of a series plot with two groups and I would like each of the two curves to be labeled. I am using the CURVELABEL option to accomplish this, but it appears that the labels overlap when the baseline values are similar. Any suggestions on how to stagger these labels? My code and output are below. Thank you in advanced!

title "Safety and Efficacy Profile for Subject 10001";
proc sgpanel data=test nocycleattrs dattrmap=attrmap;;
	panelby id / onepanel layout=rowlattice uniscale=column novarname spacing=10;
	refline 0 / axis=x lineattrs=(thickness=1 color=black);
	highlow y=mhdecod low=stdy high=endy / type=bar barwidth=0.8 lowlabel=mhlabel lowcap=lowcap highcap=highcap fillattrs=(color=CX003DF5);
	highlow y=acmdecod low=stdy high=endy / type=bar barwidth=0.8 lowlabel=cmlabel lowcap=lowcap highcap=highcap fillattrs=(color=CXED7D31);
	highlow y=aedecod low=stdy high=endy / type=bar group=severity labelattrs=(color=black) lineattrs=(color=black pattern=solid) barwidth=0.8 lowlabel=aelabel highcap=highcap attrid=Severity;
	series x=stdy y=aval / group=param attrid=Outcome curvelabel curvelabelpos=start curvelabelattrs=(color=black) lineattrs=(pattern=solid);
	rowaxis display=(nolabel noticks novalues) min=0;
	colaxis grid label='                                                 Study Day' offsetmin=0.3 values=(-28 to 210 by 7) fitpolicy=thin;
run;

Re: Series plot CURVELABEL overlapping

PGStats — Sat, 04 Aug 2018 05:22:50 GMT

Even if you stagger the curve labels, it won't be obvious which curve they are associated with. There would be room for curvelabelpos=end, which would better identify your curves.

Re: Series plot CURVELABEL overlapping

hsaul — Mon, 06 Aug 2018 17:48:39 GMT

Thanks for your feedback! Unfortunately, since I am generating this for multiple subjects, the data could go either way and the overlap is just as likely to occur at the end as the beginning.

If there is a solution for staggering, I thought I might be able to color code the labels to match the curves so that they could be easily identifiable. Open to any other suggestions though!

Re: Series plot CURVELABEL overlapping

ballardw — Mon, 06 Aug 2018 19:47:01 GMT

If your data is likely to be close often enough then perhaps you should not be excluding that bit from the legend.

Re: Series plot CURVELABEL overlapping

JeffMeyers — Tue, 07 Aug 2018 14:49:23 GMT

You have so much white space to the left of this graph, would you be able to just fit a KEYLEGEND for this plot into there alone?

Re: Series plot CURVELABEL overlapping

Jay54 — Tue, 07 Aug 2018 15:39:57 GMT

Curve labels do not have collision avoidance. However, data labels do. One work around would be to display datalabels on your series plot only for the first or last point by creating a label variable that has the curve value only for the first or last point. The labels should avoid collision. If the labels are not too close, the will be put in the upper right position.

Simple sample code:

data stocks;
  set sashelp.stocks(where=(date > '01Jan2004'd));
  if date = '01Dec05'd then label=stock;
run;

proc sgplot data=stocks;
  series x=date y=close / group=stock datalabel=label;
run;

Re: Series plot CURVELABEL overlapping

hsaul — Wed, 08 Aug 2018 01:00:30 GMT

Sanjay - This is very helpful and an elegant workaround! Thanks very much!

Re: Series plot CURVELABEL overlapping

Jay54 — Wed, 08 Aug 2018 14:59:38 GMT

Good to know it works. Now, if you want better control on the position of the labels, you could instead overlay a TEXT plot with the same idea. However, now you can set a position column in the data for each label, one as TOPLEFT, one as BOTTOMLEFT. Now, you can get the two clean labels on the left, one above, one below without collision. However, note this idea may work only for your specific 2 label case with coincident starting point.

text x=x y=y text=label / position=position;