topic Re: How to display values for ticks on axis as percentage (e.g. 8%) in a scatter plot in Graphics Programming

How to display values for ticks on axis as percentage (e.g. 8%) in a scatter plot

Lao_feng — Tue, 07 Aug 2018 01:15:29 GMT

Dear all,

Does anyone know how to specify the value for ticks on axis as percentage (e.g. '8%') instead of number (e.g. '8') for a scatter plot ?

I used 'Proc sgplot' to create a scatter plot for proportion of diabetes in male and female. The Y axis is proportion and I want to display percentage here. Thanks a lot!

Best,

Feng Liang

Re: How to display values for ticks on axis as percentage (e.g. 8%) in a scatter plot

Jagadishkatam — Tue, 07 Aug 2018 01:49:07 GMT

Could you please send the proc sgplot code you are using. Before that you might try using the proc format as below

proc format;
value pct
low - 1='1%'
2-<3='2%'
3-<4='4%';
run;

you can extend the format. then you need to apply this format in the sgplot procedure for the y axis variable.

Re: How to display values for ticks on axis as percentage (e.g. 8%) in a scatter plot

Lao_feng — Tue, 07 Aug 2018 02:14:47 GMT

Dear Jagadishkatam,

The following are my codes:

data pdi;
INPUT Gender $ Proportion;
cards;
Male 10.6
Female 28.0
;
RUN;

PROC SGPLOT DATA=pdi;
SCATTER Y=Proportion X=gender/ datalabel=proportion ;
YAXIS VALUES=(0 TO 40 BY 10) LABEL="Proportion " LABELATTRS=(size=13 );
XAXIS LABEL="Proportion of diabetes by gender" ;
RUN;QUIT;

The values for variable 'proportion' is percentage (10.6% and 28%) itself. I cannot categorize them again. Thanks!

Regards,

Feng Liang

Re: How to display values for ticks on axis as percentage (e.g. 8%) in a scatter plot

Lao_feng — Tue, 07 Aug 2018 02:17:17 GMT

Sorry, the codes were not posted properly. I post them again.

data pdi;
INPUT Gender $ Proportion;
cards;
Male 10.6
Female 28.0

;
RUN;

PROC SGPLOT DATA=pdi;
SCATTER Y=Proportion X=gender/ datalabel=proportion ;
YAXIS VALUES=(0 TO 40 BY 10) LABEL="Proportion " LABELATTRS=(size=13 );
XAXIS LABEL="Proportion of diabetes by gender" ;
RUN;QUIT;

Thanks!

Feng Liang

Re: How to display values for ticks on axis as percentage (e.g. 8%) in a scatter plot

Jagadishkatam — Tue, 07 Aug 2018 02:26:18 GMT

In that case you coudl try something as below

data pdi;
INPUT Gender $ Proportion;  
cards;
Male    10.6  
Female  28.0
;
RUN;

proc format;
value pct
10.6='10.6%'
28.0='28.0%'
;

use this format on the variable in proc sgplot

Re: How to display values for ticks on axis as percentage (e.g. 8%) in a scatter plot

JeffMeyers — Tue, 07 Aug 2018 14:32:52 GMT

Hello,

I would just divide your proportions by 100 and add the percent12.1 format to it. I had to adjust the y axis values (didn't change your label yet) afterwards. Here's what I got with your code:

 data pdi;
input gender $ proportion;
cards;
Male 10.6
Female 28.0
;
run;
data pdi2;
set pdi;
proportion=proportion/100;
run;

ods graphics /reset;

proc sgplot data=pdi2;
scatter y=proportion x=gender / datalabel=proportion;
yaxis values=(0 to 0.4 by 0.1) Label='Proportion' labelattrs=(size=13);
xaxis label='Proportion of diabetes by gender';
format proportion percent12.1;
run;

Re: How to display values for ticks on axis as percentage (e.g. 8%) in a scatter plot

Lao_feng — Wed, 08 Aug 2018 05:31:42 GMT

Dear JeffMeyers,

Thank you very much !

Regards,

Feng Liang