topic Re: Adding empty cells in SGPANEL in Graphics Programming

Adding empty cells in SGPANEL

jimhorne — Thu, 02 Aug 2018 14:32:54 GMT

I have a 3x3 Layout Lattice graph but I only have 7 graphs I produce for it. How can I make the only graph on the third row appear on the right or in the center instead of on the left as it will normally?

Re: Adding empty cells in SGPANEL

ballardw — Thu, 02 Aug 2018 15:08:32 GMT

@jimhorne wrote:

I have a 3x3 Layout Lattice graph but I only have 7 graphs I produce for it. How can I make the only graph on the third row appear on the right or in the center instead of on the left as it will normally?

It would help to show the code you are currently using.

To control that kind of order you may want to investigate LAYOUT DATALATTICE or DATAPANEL where the row/column positions are controlled by the values of one or two classification variables.

Re: Adding empty cells in SGPANEL

DanH_sas — Thu, 02 Aug 2018 21:12:38 GMT

Here is one way to do it using the SPARSE option on the PANELBY statement, which will render cells that contain no observations:

/* Your data */
data example;
do p = 1 to 7;
   do x=1 to 10;
      y=ranuni(123);
      output;
   end;
end;

/* Add something that will sort */
/* before the last cell. */
data movecell;
set example end=eof;
output;
if eof then do;
  p=6.5;
  x=.;
  y=.;
  output;
end;

/* Clear the header */
proc format;
  value clear 6.5=" ";
run;

proc sgpanel data=movecell;
format p clear.;
panelby p / sparse columns=3 onepanel novarname;
scatter x=x y=y;
run;

Re: Adding empty cells in SGPANEL

jimhorne — Fri, 03 Aug 2018 11:55:11 GMT

Thanks Dan. That is an elegant solution to the question I asked. It also points out to me that I really asked the wrong question because what I really need is how to do it in GTL not in SGPANEL. Unfortunately for my peace of mind that is not the question I meant to ask.

Re: Adding empty cells in SGPANEL

jimhorne — Fri, 03 Aug 2018 11:58:37 GMT

I didn't show code because I am really looking for a generic solution. And while DATALATTICE or DATAPANEL might work, they require the classification variables to be the same across cells. The overwhelming majority of graphs I build consist of independent cells and unfortunately those layouts will not work in that circumstance.

Re: Adding empty cells in SGPANEL

DanH_sas — Fri, 03 Aug 2018 14:28:48 GMT

Unlitmately, the SGPANEL is using the DATAPANEL or DATALATTICE layouts of GTL, so this solution would work there as well.

Re: Adding empty cells in SGPANEL

jimhorne — Fri, 03 Aug 2018 14:37:55 GMT

So it sounds as if there is not a good way to insert empty cells if each cell is independent of the others, but only if they share common classification variables. While it's not the answer I wanted it's good to know. Thanks

Re: Adding empty cells in SGPANEL

DanH_sas — Fri, 03 Aug 2018 14:41:15 GMT

In GTL, you can use a LATTICE layout for independent plots, but a DATALATTICE is for classification variables. Sound like you really want a LATTICE, which would require you to use GTL.

Re: Adding empty cells in SGPANEL

jimhorne — Fri, 03 Aug 2018 15:06:40 GMT

And LAYOUT LATTICE is what I use today. I was just hoping for a way in it where I could control the position of blank cells instead of having it done for me. Sometimes I would like to group cells different than the default orfer. It's only an issue for me when I have rows with not enough cells to fill them up.

Re: Adding empty cells in SGPANEL

DanH_sas — Fri, 03 Aug 2018 16:42:02 GMT

The way you do that in GTL with a LAYOUT LATTICE is to put a blank ENTRY in the cell. Here is a simple example:

proc template;
define statgraph layout_test;
begingraph;
layout lattice / columns=3;
layout overlay;
   barchart x=age y=weight / stat=mean;
endlayout;
entry " ";
layout overlay;
   barchart x=age y=height / stat=mean;
endlayout;
endlayout;
endgraph;
end;
run;

proc sgrender data=sashelp.class template=layout_test;
run;