topic Re: Multiple independent scatter plots in Graphics Programming

Multiple independent scatter plots

matt23 — Fri, 22 Jun 2018 15:12:16 GMT

Hi, I'd like to have all 4 of my scatter plots in one window like this:

I have 4 scatter plots for 4 different seasons. Here's an example of a scatter plot for winter:

proc sgplot data=dataname (where=(Month in(12,1,2)));
scatter x=Temperature y=Load;
xaxis label="Temperature (degrees F)";
yaxis label="Load (MW)";
title 'Load vs Temperature';
run;

Re: Multiple independent scatter plots

ChrisHemedinger — Fri, 22 Jun 2018 15:20:51 GMT

Check PROC SGPANEL, which allows a PANELBY variable so you can segment your plots. This works if all X/Y axis variables are the same for each plot, and you're just grouping with another variable.

Otherwise, you could use PROC TEMPLATE to design a custom layout. ODS Graphics Designer is a point-and-click interface that can help you design this with a minimum of manual coding.

Re: Multiple independent scatter plots

ballardw — Fri, 22 Jun 2018 15:27:35 GMT

The image you show is from SGSCATTER online documentation example 2.

Since you want to create a separate graph based on the value of a different variable than is involved in the actual plot then SGPANEL with a custom format for your MONTH variable to get groups probably a good solution. Something like:

proc format library=work;
value season
12,1,2 = 'Winter'
3,4,5 = 'Spring'
6,7,8 = 'Summer'
9,10,11 = 'Fall';
run;
proc sgpanel data=dataname ;
   panelby month /layout=panel rows=2 columns=2 onepanel ;
   format month season.;
   scatter x=Temperature y=Load;
   colaxis label="Temperature (degrees F)";
   rowaxis label="Load (MW)";
   title 'Load vs Temperature';
run;

may get you started.

Re: Multiple independent scatter plots

matt23 — Fri, 22 Jun 2018 15:49:18 GMT

that is amazing, thank you