topic proc sgplot with 2 y axes in Graphics Programming

proc sgplot with 2 y axes

shari — Thu, 12 Apr 2018 19:50:42 GMT

Hi,

I am trying to create a plot with two y axes. I used proc sgplot and I see the graph generated with color and symbol representation for only one y axis. Is there any way or option to show the color and symbol representation for another Y axis.

Thanks in advance.



data temp;
input ptno ady value1 value2;
cards;
100 1 10 12
100 5 15 16
100 8 20 18
;


ods listing;
proc sgplot data=temp;
scatter x=ady y=value1/group=ptno;
scatter x=ady y=value2/y2axis group=ptno;
yaxis min=0 label='Y1 axis' values=(0 to 20 by 2);
y2axis min=0 label='Y2 axis' values=(0 to 20 by 2);
run;

Re: proc sgplot with 2 y axes

DanH_sas — Thu, 12 Apr 2018 20:46:08 GMT

I'm not entirely sure of what you want, but I think you might want separate legends for each plot. Here is an example:

data temp;
input ptno ady value1 value2;
cards;
100 1 10 12
100 5 15 16
100 8 20 18
;

ods listing;
proc sgplot data=temp;
scatter x=ady y=value1/group=ptno name="v1";
scatter x=ady y=value2/y2axis group=ptno name="v2";
keylegend "v1" / title="Y Axis" position=bottomleft;
keylegend "v2" / title="Y2 Axis" position=bottomright;
yaxis min=0 label='Y1 axis' values=(0 to 20 by 2);
y2axis min=0 label='Y2 axis' values=(0 to 20 by 2);
run;

Re: proc sgplot with 2 y axes

shari — Fri, 13 Apr 2018 00:38:53 GMT

Thank you. It worked as expected. Sorry for not being much clear.