topic Re: User-defined Formats in PROC SGPLOT, cannot use discrete axis in Graphics Programming

User-defined Formats in PROC SGPLOT, cannot use discrete axis

sm4 — Thu, 22 Mar 2018 15:23:35 GMT

Hello,

I guess I'm hoping there's someone who might know of some updated solution/workaround to the already-documented issue of user-defined picture formats not rendering in proc sgplot.

I am using picture formats to generate a Mon-YY format with a dash, courtesy of another kind user: https://communities.sas.com/t5/General-SAS-Programming/MONTH-YY-and-MON-YY-date-format/m-p/446015/highlight/false#M55205

Realized after accepting the solution that they won't render in proc sgplot. Like the user in the first link above, I can't format the dataset outside and then plot that discretely (as suggested) because I'm using a slightly tricky time axis, was difficult enough to get it to do what I want without introducing the formatting issue:

		xaxis display=(nolabel) type= time notimesplit fitpolicy= rotate interval= semiyear values= ('01JAN2000'd to &today. by semiyear)  valuesformat= MONYY5.;

Currently I'm using MONYY5., but I would like to get Mon-YY if possible.

Would appreciate any insight if anyone has any.

Thanks!

Re: User-defined Formats in PROC SGPLOT, cannot use discrete axis

Reeza — Thu, 22 Mar 2018 15:41:27 GMT

What version of SAS are you using?

Proc product_status;run;

Re: User-defined Formats in PROC SGPLOT, cannot use discrete axis

DanH_sas — Thu, 22 Mar 2018 17:56:06 GMT

What you could do is use a small data step to create a column of formatted month values. Then, use that dataset with SGPLOT, referencing that formatted variable for your category values.

Hope this helps!

Dan

Re: User-defined Formats in PROC SGPLOT, cannot use discrete axis

ballardw — Thu, 22 Mar 2018 20:18:09 GMT

Some example data and your current sgplot code might go a ways towards a solution. Especially if you can describe what is wrong with axis appearance.

I don't think I would consider that a "tricky" axis though.

Re: User-defined Formats in PROC SGPLOT, cannot use discrete axis

sm4 — Thu, 22 Mar 2018 21:20:31 GMT

9.4

Thanks!

Re: User-defined Formats in PROC SGPLOT, cannot use discrete axis

sm4 — Thu, 22 Mar 2018 22:29:55 GMT

Thanks for your response!
Yeah, I guess I meant "tricky" relative to other datasets that I easily changed to a discrete axis for.

I am trying to automate in SAS a graph produced by my organization. I basically have a dataset with a value for every month since, say, Jan 2000 until Dec 2017. I want my x axis values to be every 6 months starting with a month I choose, e.g. Feb-01 Aug-01 Feb-02 Aug-02 etc, with a line marker for every month's observation, not just Feb and Aug. I was able to establish this with the time type x-axis statement above after some trial and error (I am new to graphing in SAS hence it was tricky) but it doesn't give me the Mon-YY formatting I want.

I can get the Mon-YY formatting I want if I drop all but Feb and Aug observations from my dataset, apply the user-defined format, and then plot discretely. But then I will lose the line-markers for non-Feb/Aug months.

It's not such a big deal, but since I'm trying to replicate exactly what the organization already does and since it seems like it should be doable, I want to see if I can get both Mon-YY formatting as well as markers for every month (mutually exclusive in my trials so far). But again, not a big deal if it's not possible.

Sample data would just be one record for every month from, say, Jan 2000 until Dec 2017, where month is formatted as date9 and value can be anything. I'm trying to be cautious about what I share or else I would put something here.

Thanks very much!

Re: User-defined Formats in PROC SGPLOT, cannot use discrete axis

sm4 — Thu, 22 Mar 2018 22:34:55 GMT

Sorry, forgot to include my sgplot code:

      proc sgplot data= temp.figure noborder nowall pad=(left= 5pct right= 5pct) noautolegend;
           series x= month y= change/ lineattrs= (color= black thickness = 2) markers markerattrs= (symbol= diamondfilled color= darkblue);
           xaxis display=(nolabel) type= time notimesplit fitpolicy= rotate interval= semiyear values= ('01FEB2000'd to &today. by semiyear) valuesformat= MONYY5. valueattrs= (family= albany size= 12px weight=bold) offsetmin= 0 offsetmax= 0;
           yaxis label= 'Label' labelattrs= (family= albany weight= bold size= 9.5pt) valueattrs= (family= albany weight=bold) values= (-0.28 to 0.16 by 0.02) valuesformat= PERCENTN10.1;
           band x= month upper= 0.15 lower= -0.23 / fillattrs= (color= aliceblue) transparency= 0.5; 
           refline 0 / lineattrs=(color=LIGB);
      run;

Re: User-defined Formats in PROC SGPLOT, cannot use discrete axis

sm4 — Thu, 22 Mar 2018 22:37:05 GMT

Thanks for your response!

I think this might be the same issue where if I format it beforehand, I won't be able to plot it on the time type x-axis since it won't be a sasdate anymore?

Re: User-defined Formats in PROC SGPLOT, cannot use discrete axis

DR_Majeti — Tue, 27 Mar 2018 10:21:30 GMT

Hi,

Please try to use FORMAT statement in the proc sgplot.

Ex: Format xaxisvariable MONYY5./predefined format created ;

Re: User-defined Formats in PROC SGPLOT, cannot use discrete axis

sm4 — Tue, 27 Mar 2018 14:37:18 GMT

Thanks for your response!

Tried this out (removing the valuesformat= option on the xaxis statement), it gives the same issue. The user-generated format doesn't load, showing only '0B-%0y'.

Re: User-defined Formats in PROC SGPLOT, cannot use discrete axis

Reeza — Tue, 27 Mar 2018 14:44:37 GMT

It is noted in the documentation that SAS custom formats do not work in GTL, so unfortunately the format you want isn't available.

You're likely correct in that converting the date will not give you what you want, but I'd try it to verify anyways.

Re: User-defined Formats in PROC SGPLOT, cannot use discrete axis

sm4 — Tue, 27 Mar 2018 15:57:04 GMT

Yeah, if you mean plotting discretely, the line-markers for non-Feb/Aug months definitely don't show up - tried it already.

Looks like this is not possible, in that case. It's good to know so that I don't spend additional time pondering it. Thank you!

Re: User-defined Formats in PROC SGPLOT, cannot use discrete axis

DR_Majeti — Wed, 28 Mar 2018 08:24:48 GMT

Please try like below,

I have created small example data.

data simple ;
do x= '01jan2018'd to '31dec2018'd by 30;
y+1;
output;
end;
run;

data fmt;
set simple;
start=x;
label=strip(substr(put(start,monyy5.),1,3))||'-'||strip(put(year(x),best.));
fmtname='chkfmt';
run;

proc format cntlin=fmt;
run;

proc sgplot data=simple;
scatter x=x y=y ;
xaxis label=' SAS defined format' ;
format x monyy7. ;
run;

proc sgplot data=simple;
scatter x=x y=y ;
xaxis label=' User defined format' values=('01jan2018'd to '31dec2018'd by 30);
format x chkfmt. ;
run;

Re: User-defined Formats in PROC SGPLOT, cannot use discrete axis

Reeza — Wed, 28 Mar 2018 14:38:02 GMT

@DR_Majeti is correct. A PICTURE format will not work, but using a 'normal' format seems to work. That's an important distinction and good to know, learn something new every day!

Re: User-defined Formats in PROC SGPLOT, cannot use discrete axis

sm4 — Wed, 28 Mar 2018 21:37:09 GMT

Am checking this out, will update here soon. Thank you!!

Re: User-defined Formats in PROC SGPLOT, cannot use discrete axis

GraphGuy — Thu, 29 Mar 2018 14:52:45 GMT

If there's no work-around for Proc Sgplot, perhaps you could create the plot using Proc Gplot (?)

Re: User-defined Formats in PROC SGPLOT, cannot use discrete axis

Reeza — Thu, 29 Mar 2018 15:04:46 GMT

I ran and verified @DR_Majeti solution, it does work as intended.

Re: User-defined Formats in PROC SGPLOT, cannot use discrete axis

Jay54 — Thu, 29 Mar 2018 15:06:54 GMT

SGPLOT / GTL do support formats for discrete axis including UDF and Picture format. I have used some simple picture formats (to change sign of the value) with SGPLOT. The format should be provided on the XAXIS statement, to avoid categorization. However, your mileage will vary because the Java format code does not support all possibilities.

Some workarounds are possible. See this article on Stock Chart. The idea here is that the x-axis can be replaced by an XAXISTABLE displaying the values that you want coming from a character column in the data set. The formatting to create the character column is done in SAS data step code, so all formats should work. SGPLOT only draws what you have already computed using the XAXISTABLE.

Re: User-defined Formats in PROC SGPLOT, cannot use discrete axis

sm4 — Thu, 29 Mar 2018 17:16:38 GMT

Worked!

Instead of using it through a separate format statement I used it with the "valuesformat=" option on the xaxis statement - the former caused my axis to change from semi-yearly to yearly, for some reason. Using it with valuesformat works perfectly.

Thank you very, very much.

Re: User-defined Formats in PROC SGPLOT, cannot use discrete axis

sm4 — Fri, 30 Mar 2018 19:04:14 GMT

Thanks for your reply!

Looks like regular user-created formats will show up but picture formats won't, based on my experience and what documentation/others say. The link you shared is really interesting - did not know it was possible to suppress the actual axis and bring in something else. This may be very relevant for separate problems I've been having, thank you!