How do I change the color of response surface plots?

hjong — Tue, 27 Feb 2018 19:21:53 GMT

I want to change the color of the response surface plots generated using proc rsreg. I also want to include a contour plot below the response surface plot in the same figure. What do I need to include in my code? Here's my code.

proc rsreg data=DOE plots=surface(3d at (Temp=30) unpack);
model T1 = Temp Time Speed;
run;

Thank you.

Re: How do I change the color of response surface plots?

WarrenKuhfeld — Tue, 27 Feb 2018 22:15:42 GMT

You can edit the color model in the template. The example code shows how you can use a DATA step to perform the edit.

data smell;
   input Odor T R H @@;
   label
      T = "Temperature"
      R = "Gas-Liquid Ratio"
      H = "Packing Height";
   datalines;
 66 40 .3 4     39 120 .3 4     43 40 .7 4     49 120 .7  4
 58 40 .5 2     17 120 .5 2     -5 40 .5 6    -40 120 .5  6
 65 80 .3 2      7  80 .7 2     43 80 .3 6    -22  80 .7  6
-31 80 .5 4    -35  80 .5 4    -26 80 .5 4
;

ods trace on;
ods html body='b.html';
ods graphics on;
proc rsreg data=smell plots=surface;
   model Odor = T R H / lackfit;
run;

proc template;
   delete Stat.Rsreg.Graphics.ContourPanel;
   source Stat.Rsreg.Graphics.ContourPanel / file='t';
quit;

data t(keep=l);
   infile 't' end=eof;
   input;
   if _n_ eq 1 then call execute('proc template;');
   _infile_ = tranwrd(_infile_, 'colormodel=TWOCOLORRAMP',
                      'colormodel=(red orange purple blue)');
   call execute(_infile_);
   if eof then call execute('quit;');                      
   run;

proc rsreg data=smell plots=surface;
   model Odor = T R H / lackfit;
run;
ods html close;

topic Re: How do I change the color of response surface plots? in Graphics Programming

How do I change the color of response surface plots?

Re: How do I change the color of response surface plots?