topic Re: sgplot vbar data label of sum in Graphics Programming

sgplot vbar data label of sum

Melk — Fri, 27 Oct 2017 20:32:46 GMT

I am running an sgplot vbar where the stat is the mean and I would like to label each vbar with the sample size in each group. is there a way I can do this, something like datalabel=(stat=sum) [but this does not work].

Re: sgplot vbar data label of sum

DanH_sas — Fri, 27 Oct 2017 20:44:38 GMT

How about something like this?

proc sgplot data=sashelp.class;
vbar age / response=weight stat=mean;
xaxistable weight / stat=freq location=inside
                    position=top;
run;

Re: sgplot vbar data label of sum

Melk — Fri, 27 Oct 2017 20:54:11 GMT

I am formatting the response variable as a percent since it is a binary variable, and I want the proportion of 1s (vs 0s). I want the total sample size in each group to be displayed per bar (num of 0s + 1s).

Because of this format I think, when I run with your suggestions it is giving me percentages rather than counts. Am I able to employ 2 different formats for the same variable within a proc block?

proc sgplot data=dat;
vbar days / response=mort stat=mean;
format mort percent6.2;
run;

Re: sgplot vbar data label of sum

DanH_sas — Fri, 27 Oct 2017 21:02:07 GMT

What version of SAS are you using?

Re: sgplot vbar data label of sum

DanH_sas — Fri, 27 Oct 2017 21:07:50 GMT

I was talking with Sanjay about this one, and he pointed out that another alternative would be to just pre-compute the data in PROC MEANS and use a VBARPARM to render it. Here's what that would look like:

proc means data=sashelp.class nway;
class age;
var weight;
output out=temp mean=weight_mean n=weight_n;
run;

proc sgplot data=temp;
vbarparm category=age response=weight_mean / datalabel=weight_n;
run;

Re: sgplot vbar data label of sum

Melk — Fri, 27 Oct 2017 21:14:12 GMT

Worked beautifully - much appreciated.

Re: sgplot vbar data label of sum

Melk — Fri, 27 Oct 2017 21:14:29 GMT

SAS 9.4