topic Re: KM plot with a nested plot as if it were an INSET. in Graphics Programming

KM plot with a nested plot as if it were an INSET.

data_null__ — Fri, 15 Sep 2017 01:17:48 GMT

This format can be seen in the New England Journal of Medicine.

Can I make this with ODS graphics, GTL?

Re: KM plot with a nested plot as if it were an INSET.

WarrenKuhfeld — Fri, 15 Sep 2017 02:46:39 GMT

I would imagine you could make a graph, store it as an image, then make the outer graph and bring in the image for the inner graph through SG Annotation. That's all that pops into my mind this close to bed time.

Re: KM plot with a nested plot as if it were an INSET.

DanH_sas — Fri, 15 Sep 2017 04:08:30 GMT

I actually demonstrate this annotation technique in the following paper, on pages 8-10:

Now You Can Annotate Your GTL Graphs! - PharmaSUG

Hope this helps!

Dan

Re: KM plot with a nested plot as if it were an INSET.

WarrenKuhfeld — Fri, 15 Sep 2017 14:49:47 GMT

Great example, Dan! Here is a simple example I worked up that illustrates the principles involved.
Very cool technique! I have never done this before. (edited since part of my code was with the text).


ods graphics on / reset=all imagename="Inset" height=120px width=160px border=off;

proc sgplot data=sashelp.class;
   hbar sex / barwidth=0.5;
   yaxis display=(nolabel);
   xaxis display=(nolabel);
run;

data anno;
   retain function "image" width 30 x1 1 y1 99 anchor "topleft"
          drawspace "wallpercent" image 'Inset.png';
run;

ods graphics on / reset=all imagename="Embedding";
proc sgplot data=sashelp.class sganno=anno noautolegend;
   styleattrs datacolors=(blue red) datasymbols=(circlefilled);
   scatter y=weight x=height / group=sex;
run;

Re: KM plot with a nested plot as if it were an INSET.

Jay54 — Fri, 15 Sep 2017 14:35:33 GMT

This would work better if you provide a size for the inset image, and make sure it is placed in the right location.

ods html close;
ods listing gpath='c:\';
ods graphics / reset width=2in height=1.5in imagename='Inset';
proc sgplot data=sashelp.class;
hbar sex / barwidth=0.5;
yaxis display=(nolabel);
xaxis display=(nolabel);
run;

data anno;
retain function "image" width 30 x1 1 y1 99 anchor "topleft"
drawspace "wallpercent" image 'c:\Inset.png';
run;

ods graphics on / reset=all imagename="Embedding";
proc sgplot data=sashelp.class sganno=anno noautolegend;
styleattrs datacolors=(blue red) datasymbols=(circlefilled);
scatter y=weight x=height / group=sex;
run;

Re: KM plot with a nested plot as if it were an INSET.

WarrenKuhfeld — Fri, 15 Sep 2017 14:46:09 GMT

Sorry. Copy and paste error on my part. Here it is including my initial statement, which does specify a size.

ods graphics on / reset=all imagename="Inset" height=120px width=160px border=off;

proc sgplot data=sashelp.class;
   hbar sex / barwidth=0.5;
   yaxis display=(nolabel);
   xaxis display=(nolabel);
run;

data anno;
   retain function "image" width 30 x1 1 y1 99 anchor "topleft"
          drawspace "wallpercent" image 'Inset.png';
run;

ods graphics on / reset=all imagename="Embedding";
proc sgplot data=sashelp.class sganno=anno noautolegend;
   styleattrs datacolors=(blue red) datasymbols=(circlefilled);
   scatter y=weight x=height / group=sex;
run;

Re: KM plot with a nested plot as if it were an INSET.

data_null__ — Fri, 15 Sep 2017 17:10:02 GMT

@DanH_sas wrote:

I actually demonstrate this annotation technique in the following paper, on pages 8-10:

Now You Can Annotate Your GTL Graphs! - PharmaSUG

Hope this helps!

Dan

Thanks so much Dan, I figured it would be annotate but I would never have known the proper options/statements without seeing your example.

Re: KM plot with a nested plot as if it were an INSET.

data_null__ — Fri, 15 Sep 2017 15:23:07 GMT

@WarrenKuhfeld wrote:


ods graphics on / reset=all imagename="Inset" height=120px width=160px border=off;

proc sgplot data=sashelp.class;
   hbar sex / barwidth=0.5;
   yaxis display=(nolabel);
   xaxis display=(nolabel);
run;

data anno;
   retain function "image" width 30 x1 1 y1 99 anchor "topleft"
          drawspace "wallpercent" image 'Inset.png';
run;

ods graphics on / reset=all imagename="Embedding";
proc sgplot data=sashelp.class sganno=anno noautolegend;
   styleattrs datacolors=(blue red) datasymbols=(circlefilled);
   scatter y=weight x=height / group=sex;
run;

Hi Warren,

Thanks for the helpful example. I think this technique is going to be very useful to me.