topic Re: ODS PDF -- 2 charts per page, titles missing on 2nd chart in Graphics Programming

ODS PDF -- 2 charts per page, titles missing on 2nd chart

PaigeMiller — Thu, 07 Sep 2017 18:31:24 GMT

Let's suppose I want to put two tables on one page using ODS PDF. Each table is to have a different title. If I use this code, the second table's title doesn't appear (as shown in the attachment). What am I doing wrong?

ods pdf file="&cdu\temp.pdf" startpage=no;
title "SASHELP.CARS";
title2 "First 10 Rows";
proc print data=sashelp.cars(obs=10);
	id make model;
	var msrp mpg_highway;
run;
title "SASHELP.CARS";
title2 "Second 10 Rows";
proc print data=sashelp.cars(firstobs=11 obs=20);
	id make model;
	var msrp mpg_highway;
run;
ods pdf close;

Re: ODS PDF -- 2 charts per page, titles missing on 2nd chart

Miracle — Thu, 07 Sep 2017 18:51:08 GMT

Maybe try ods text instead?

ods pdf reporting without page breaks

Titles are missing from pdf

Re: ODS PDF -- 2 charts per page, titles missing on 2nd chart

Reeza — Thu, 07 Sep 2017 19:02:41 GMT

Issue replicated on SAS 9.4 TS1M3.

ODS TEXT does function as a workaround but you'd have to customize the format/style which is annoying.

Re: ODS PDF -- 2 charts per page, titles missing on 2nd chart

PaigeMiller — Thu, 07 Sep 2017 20:04:06 GMT

Thank you @Miracle and @Reeza.

This now works

ods escapechar='^';
ods pdf file="&cdu\temp.pdf" startpage=no;
ods pdf text = "^{style [just=center font=(Arial) fontsize=11pt fontweight=bold color=verydarkstrongblue] SASHELP.CARS}";
ods pdf text = "^{style [just=center font=(Arial) fontsize=11pt fontweight=bold color=verydarkstrongblue] First 10 Rows}";
proc print data=sashelp.cars(obs=10);
	id make model;
	var msrp mpg_highway;
run;
ods pdf text = "^{newline 2}";
ods pdf text = "^{style [just=center font=(Arial) fontsize=11pt fontweight=bold color=verydarkstrongblue] SASHELP.CARS}";
ods pdf text = "^{style [just=center font=(Arial) fontsize=11pt fontweight=bold color=verydarkstrongblue] 2nd 10 Rows}";
proc print data=sashelp.cars(firstobs=11 obs=20);
	id make model;
	var msrp mpg_highway;
run;
ods pdf close;

Okay, I went a little crazy with the style options, but when you have a new toy, you play with it ...

Re: ODS PDF -- 2 charts per page, titles missing on 2nd chart

Reeza — Thu, 07 Sep 2017 20:14:36 GMT

Don't know if this is useful, but recently realized you can specify colours in SAS using

CX[HEXCOLOUR] which works great when trying to match company styles:

ods pdf text = "^{style [just=center font=(Arial) fontsize=11pt fontweight=bold color=Cx00aad2] First 10 Rows}";

%let cdu = C:\_localdata\temp;

ods escapechar='^';
ods pdf file="&cdu\temp.pdf" startpage=no;
ods pdf text = "^{style [just=center font=(Arial) fontsize=11pt fontweight=bold color=cxff7900] SASHELP.CARS}";
ods pdf text = "^{style [just=center font=(Arial) fontsize=11pt fontweight=bold color=cxd40072] First 10 Rows}";
proc print data=sashelp.cars(obs=10);
	id make model;
	var msrp mpg_highway;
run;
ods pdf text = "^{newline 2}";
ods pdf text = "^{style [just=center font=(Arial) fontsize=11pt fontweight=bold color=Cx00aad2] SASHELP.CARS}";
ods pdf text = "^{style [just=center font=(Arial) fontsize=11pt fontweight=bold color=Cx00aad2] 2nd 10 Rows}";
proc print data=sashelp.cars(firstobs=11 obs=20);
	id make model;
	var msrp mpg_highway;
run;
ods pdf close;

Re: ODS PDF -- 2 charts per page, titles missing on 2nd chart

PaigeMiller — Thu, 07 Sep 2017 21:44:44 GMT

This is mostly off-topic, but how would I know what my company logo color is in CX notation?

Re: ODS PDF -- 2 charts per page, titles missing on 2nd chart

Reeza — Thu, 07 Sep 2017 22:26:49 GMT

My company has a corporate style guide courtesy of communications.

Another way is to go the to company website, use the web developer tools, check the CSS (cascading style sheet) for the colours used for common things, ie text, possibly logo, specific headings etc.

Re: ODS PDF -- 2 charts per page, titles missing on 2nd chart

ballardw — Thu, 07 Sep 2017 22:44:16 GMT

@PaigeMiller wrote:

This is mostly off-topic, but how would I know what my company logo color is in CX notation?

It may be easier to use CMYK if your organization has a Pantone Color look up somewhere for a printing documents.

The SAS color code would look like: CMYKccmmyykk where

cc is the cyan component.

mm is the magenta component.

yy is the yellow component.

kk is the black component.

The components are hexadecimal numbers in the range 00–FF, where higher values are darker and lower values are brighter. This scheme allows for up to 256 levels of each color component.