topic Re: SAS Graphics - scatterplot, symbols, and confidence intervals in Graphics Programming

SAS Graphics - scatterplot, symbols, and confidence intervals

sas_user4 — Thu, 27 Jul 2017 16:16:13 GMT

Hi,

I am faily new to SAS. I have this dataset on lower (li) and upper income (ui) and year (y):

data new;

input li ui year;

datalines;

2015 1200 1360

2014 1170 1330

2013 1170 1330

2012 1140 1330

2011 1130 1320

2010 1110 1310

2009 1140 1310

2008 1120 1290

2007 1130 1300

2006 1150 1310

;

run;

I need help in writing SAS code for a scatterplot with the lower income on the vertical axis versus the year on the horizontal axis. How can I make these observations on the plot with the character v. On the same plot, what is the SAS code to show the upper income plotted against the year and how to mark these points with a ^. I want to use this idea to show confidence intervals or prediction intervals on a plot.

Thanks!

Re: SAS Graphics - scatterplot, symbols, and confidence intervals

WarrenKuhfeld — Thu, 27 Jul 2017 16:28:19 GMT

I don't much like the idea of using a caret as one of the symbols, so I did not show that, but this makes the plot you request. It does not work all that well with the data you have.

data new;
 input li ui Year;
 Income = li; type = 'Lower Income'; output;
 income = ui; type = 'Upper Income'; output;
 datalines;
2015       1200       1360
2014       1170       1330
2013       1170       1330
2012       1140       1330
2011       1130       1320
2010       1110       1310
2009       1140       1310
2008       1120       1290
2007       1130       1300
2006       1150       1310
;

proc sgplot data=new;
   reg x=year y=income / group=type cli clm;
run;

Re: SAS Graphics - scatterplot, symbols, and confidence intervals

sas_user4 — Thu, 27 Jul 2017 16:38:39 GMT

Thanks Warren. Is this code correct:
x*year=income
Is this correct?

##- Please type your reply above this line. Simple formatting, no
attachments. -##

Re: SAS Graphics - scatterplot, symbols, and confidence intervals

WarrenKuhfeld — Thu, 27 Jul 2017 16:46:52 GMT

I believe that is a form of syntax for GPLOT, which is part of SAS/GRAPH and has its roots in 1980s technology. I showed you PROC SGPLOT, which is part of Base SAS and is based on modern technology. Here are a couple more variations on the theme.

proc sgplot data=new;
   reg x=year y=income / group=type cli clm;
   keylegend / title=' ';
run;

proc sgplot data=new;
   reg x=year y=income / group=type cli clm nomarkers legendlabel=' ' name='a';
   scatter x=year y=income / group=type markerchar=type legendlabel=' ';
   format type $1.;
   keylegend 'a' / title=' ';
run;

Re: SAS Graphics - scatterplot, symbols, and confidence intervals

WarrenKuhfeld — Thu, 27 Jul 2017 16:51:08 GMT

Actually, your data set had the variables wrong. This should work better.

data new;
 input Year li ui;
 Income = li; type = 'Lower Income'; output;
 income = ui; type = 'Upper Income'; output;
 datalines;
2015       1200       1360
2014       1170       1330
2013       1170       1330
2012       1140       1330
2011       1130       1320
2010       1110       1310
2009       1140       1310
2008       1120       1290
2007       1130       1300
2006       1150       1310
;

ods html body='b.html';
proc sgplot data=new;
   reg x=year y=income / group=type cli clm;
   keylegend / title=' ';
run;

proc sgplot data=new;
   reg x=year y=income / group=type cli clm nomarkers legendlabel=' ' name='a';
   scatter x=year y=income / group=type markerchar=type legendlabel=' ';
   format type $1.;
   keylegend 'a' / title=' ';
run;
ods html close;

Re: SAS Graphics - scatterplot, symbols, and confidence intervals

Rick_SAS — Thu, 27 Jul 2017 17:03:03 GMT

If I understand what you are asking, you can use the HIGHLOW statement to create a graph that displays interval estimates. Here is an example that uses your original data:

data new;
 input year li ui;
 datalines;
2015       1200       1360
2014       1170       1330
2013       1170       1330
2012       1140       1330
2011       1130       1320
2010       1110       1310
2009       1140       1310
2008       1120       1290
2007       1130       1300
2006       1150       1310
 ;
run;

proc sgplot data=new;
   highlow x=year low=li high=ui / highcap=openarrow lowcap=openarrow;
run;

Re: SAS Graphics - scatterplot, symbols, and confidence intervals

sas_user4 — Thu, 27 Jul 2017 17:18:39 GMT

Warren:
I don't understand why when I run your code, SAS tells me there are 20
observations while there are only 10!

##- Please type your reply above this line. Simple formatting, no
attachments. -##

Re: SAS Graphics - scatterplot, symbols, and confidence intervals

WarrenKuhfeld — Thu, 27 Jul 2017 17:21:27 GMT

Rather than writing out two income variables like you did origially, I wrote out one income variable of interest with two observations for each year. This kind of grouped data set is often the right form for ODS Graphics, although there is often more than one way to do things.

Re: SAS Graphics - scatterplot, symbols, and confidence intervals

sas_user4 — Thu, 27 Jul 2017 17:22:23 GMT

Rick_SAS:

Thank you, I run the code and here is the error message:

WARNING: No output destinations active.

And no graph was produced!

My question is that I need to plot lower income (Y axis) and Year (X axis) and then upper income against year in the same plot. Hope it is clearer now.

Re: SAS Graphics - scatterplot, symbols, and confidence intervals

sas_user4 — Thu, 27 Jul 2017 17:25:02 GMT

Thanks Warren. I hope you have patience but can I ask you how your code (using reg) is different than mine (x*y=z) in terms of the output?

Re: SAS Graphics - scatterplot, symbols, and confidence intervals

WarrenKuhfeld — Thu, 27 Jul 2017 17:29:05 GMT

'x*y=z' doesn't do anything. As before, I am guessing you are referring to PROC GPLOT. I have forgotten almost everything I ever knew about it and never recommend it. As I recall, GPLOT has no mechanism for linear regression functions, but I could very well be wrong. I was showing you how to fit regression models for each group. Rick thought you might want something different. Whatever you want, if it is a scatter plot, PROC SGPLOT is the procedure that you should be learning.

Re: SAS Graphics - scatterplot, symbols, and confidence intervals

sas_user4 — Thu, 27 Jul 2017 17:38:17 GMT

Thanks Warren! You are correct, I use gplot:

proc gplot data=new;
title 'Scatter Plot of Year and li with ui plotted against year';
plot year*li=ui / regeqn;
run;

This is snapshot of the graph using gplot

Re: SAS Graphics - scatterplot, symbols, and confidence intervals

sas_user4 — Thu, 27 Jul 2017 18:09:23 GMT

How about this code?

goptions reset = all;

symbol1 v=^ ;

symbol2 v=v;

proc sgplot data =new;

scatter x=year y=lq ;

scatter x=year y=uq;

run;

quit;

and how to produde these symbols (^) and (v)?

Thakns

Re: SAS Graphics - scatterplot, symbols, and confidence intervals

WarrenKuhfeld — Thu, 27 Jul 2017 18:27:27 GMT

There are cleaner ways, but I have to run to a meeting, and this is the way I remember off of the top of my head. Your SAS/GRAPH statements have no effect on ODS Graphics.

data new;
 input Year li ui;
 v = 'v';
 c = '^';
 datalines;
2015       1200       1360
2014       1170       1330
2013       1170       1330
2012       1140       1330
2011       1130       1320
2010       1110       1310
2009       1140       1310
2008       1120       1290
2007       1130       1300
2006       1150       1310
;

ods html body='b.html';
proc sgplot data =new noautolegend;
  scatter x=year y=li / markerchar=v;
  scatter x=year y=ui / markerchar=c;
run;
ods html close;

Re: SAS Graphics - scatterplot, symbols, and confidence intervals

sas_user4 — Thu, 27 Jul 2017 18:47:39 GMT

Thanks a lot Warren. This is excellent but how can I add the confidence
limits (clm cli)? Are these options are only available using "reg"?

Re: SAS Graphics - scatterplot, symbols, and confidence intervals

Rick_SAS — Thu, 27 Jul 2017 19:08:10 GMT

I think you might enjoy reading a basic introduction to the SG (=statistical graphics) procedures. It will give you an understanding of how different statements work.

A gentle introduction is Slaughter and Delwiche (2015), "Graphing Made Easy with SGPLOT and SGPANEL Procedures"
If you are previously experienced with SAS/GRAPH, you might enjoy Horne (2012) "Converting SAS/GRAPH to ODS Graphics."
Lastly, the documentation for PROC SGPLOT enables you to look up the syntax for the SCATTER and REG procedures and see which options are in each: Doc for PROC SGPLOT

Re: SAS Graphics - scatterplot, symbols, and confidence intervals

sas_user4 — Thu, 27 Jul 2017 19:25:45 GMT

Thanks a lot, Rick!

Re: SAS Graphics - scatterplot, symbols, and confidence intervals

WarrenKuhfeld — Thu, 27 Jul 2017 20:42:06 GMT

proc sgplot data=new noautolegend nocycleattrs;
  symbolchar char='2038'x name=c;
  symbolchar char='0087'x name=v;
  reg x=year y=li / cli clm nomarkers;
  reg x=year y=ui / cli clm nomarkers;
  scatter x=year y=li / markerchar=v;
  scatter x=year y=ui / markerchar=c;
run;

Re: SAS Graphics - scatterplot, symbols, and confidence intervals

sas_user4 — Fri, 28 Jul 2017 00:46:39 GMT

Thanks Warren but the code did not work! I appreciate your help.

Re: SAS Graphics - scatterplot, symbols, and confidence intervals

WarrenKuhfeld — Fri, 28 Jul 2017 01:05:28 GMT

It makes regression lines, confidence limits, prediction limits, and the special symbols that you want. Either you are using a really old SAS release that does not support the statements I provided, or I don't know what you want. Either way, I tested my code, and it does work. Rick gave you some references. I also suggest searches for the "SAS Graphically Speaking" blog and my basic book "Basic ODS Graphics Examples". Cheers.