topic Re: sas GRAPH Hbar with repeating period in Graphics Programming

sas GRAPH Hbar with repeating period

PSIOT — Thu, 29 Jun 2017 11:58:30 GMT

Dear all,

i would like to perform the graph in attachments.

I thought that it was possible usng Hbar with sgplot, but it does not.

The problem is that some period are repeating (in this case "Home").

Do you think that it was possible with SAS v9.4? What procedure?

Thanks for your support

Re: sas GRAPH Hbar with repeating period

RW9 — Thu, 29 Jun 2017 12:08:13 GMT

Maybe have a look through this blog:

http://blogs.sas.com/content/graphicallyspeaking/

Has loads of examples of all types of graphs.

Re: sas GRAPH Hbar with repeating period

PSIOT — Thu, 29 Jun 2017 13:17:21 GMT

Thank you

Re: sas GRAPH Hbar with repeating period

BrunoMueller — Thu, 29 Jun 2017 13:32:09 GMT

I suggest to use the HIGHLOW plot statement, you have to prepare the data accordingly.

See below for an example, that gives you some ideas:

data highlow;
  infile cards dlm="," dsd missover;
  input
    patient : $32. low high type $ labelPoint labelValue $
  ;
  cards;
patient1 someDate,0,20,hospital,10,20
patient1 someDate,20,40,ward,,
patient1 someDate,40,50,hospital,,
patient1 someDate,50,52,home,,
patient1 someDate,52,55,ward,53.5,abc
patient2 01jan2010-25sep2010,0,25,hospital,,
patient2 01jan2010-25sep2010,25,45,home,,
patient2 01jan2010-25sep2010,45,46,ward,,
;

proc sgplot data=highlow;
  highlow y=patient low=low high=high / type=bar group=type;
  text y=patient x=labelPoint text=labelValue / position=center;
  yaxis type=discrete fitpolicy=splitalways;
run;

Re: sas GRAPH Hbar with repeating period

PSIOT — Thu, 29 Jun 2017 14:59:16 GMT

Thank you,

i try to put the legend in top of the graph and one line with this sentence:

keylegend / position=top down=1;

But now i have Patient with different type and still on two rows for legends.

Can you help me?

Re: sas GRAPH Hbar with repeating period

BrunoMueller — Thu, 29 Jun 2017 15:41:39 GMT

Add the NAME= option to your plot statements, then in the KEYLEGEND statement you can say for which plot statements you would like to have a legend.

Sample:

proc sgplot data=highlow;
  highlow y=patient low=low high=high / type=bar group=type name="hl";
  text y=patient x=labelPoint text=labelValue / position=center name="txt";
  yaxis type=discrete fitpolicy=splitalways;
  keylegend "hl" / position=top  down=1 ;
run;

The placement might have something to do with space that is available, try to make your graph bigger.

Re: sas GRAPH Hbar with repeating period

PSIOT — Fri, 30 Jun 2017 07:50:34 GMT

Thank you again!

It's perfect.