topic Re: Now to create scatter plot like this? in Graphics Programming

Now to create scatter plot like this?

JohnChen_TW — Wed, 15 Mar 2017 02:50:56 GMT

HI, dose anyone has insight to create the following figure?

Re: Now to create scatter plot like this?

Jagadishkatam — Wed, 15 Mar 2017 03:41:06 GMT

We could try the sgplot procedure as below, I am assuming that the graph is overlapping of scatter plot on box plot with mean. If it is the case the below procedure should help.

proc sgplot data=have;

scatter x=feed_type y=weight / markerattrs = (size = 2 symbol = circlefilled); /*this will be the scatter plot*/

vbox weight / category=feed_type; /*this will create the box plot with mean*/

quit;

run;

Re: Now to create scatter plot like this?

Reeza — Wed, 15 Mar 2017 03:54:34 GMT

Looks like variation on a box plot.

http://blogs.sas.com/content/graphicallyspeaking/2012/05/07/unbox-your-box-plots/

Re: Now to create scatter plot like this?

PGStats — Wed, 15 Mar 2017 03:54:45 GMT

Here is an approaching example:

proc sql;
create table class as
select *, median(weight) as med
from sashelp.class
group by age;
quit;

proc sgplot data=class noautolegend;
vbox med / category=age nomean nomedian nocaps
    lineattrs=(color=red thickness=2);
scatter y=weight x=age / markerattrs=(symbol=circlefilled);
xaxis type=discrete;
run;

Re: Now to create scatter plot like this?

JohnChen_TW — Wed, 15 Mar 2017 04:06:34 GMT

Hi Jagadishkatam,

It seems that the overlapping scatter plot and box plot is not worked.
Please see the SAS log below.
Thanks for your reply.

By the way, I'm using SAS 9.3.

Re: Now to create scatter plot like this?

PGStats — Wed, 15 Mar 2017 04:23:46 GMT

I guess in 9.3 you could cheat this way:

proc sql;
create table class as
select *, median(weight) as med
from sashelp.class
group by age;
quit;

proc sgplot data=class noautolegend;
scatter x=age y=med / yerrorlower=med yerrorupper=med 
    markerattrs=(size=0) errorbarattrs=(thickness=2 color=red);
scatter y=weight x=age / markerattrs=(symbol=circlefilled color=blue);
run;

Re: Now to create scatter plot like this?

JohnChen_TW — Wed, 15 Mar 2017 05:08:50 GMT

Hi PG Stats,

Thanks for your solution.
Another question, how to lengthen the length of 'mean'?

Re: Now to create scatter plot like this?

PGStats — Wed, 15 Mar 2017 05:12:49 GMT

I don't know. Seems to be proportional to line thickness.

Re: Now to create scatter plot like this?

JohnChen_TW — Wed, 15 Mar 2017 05:36:21 GMT

Okay. I will try.
According to your reply, SAS 9.3 cannot overlay vbox and scatter plot, right?

Re: Now to create scatter plot like this?

Jay54 — Wed, 15 Mar 2017 14:56:40 GMT

If you know the value for drawing the mean or median (the red line), and are using SAS 9.3, I suggest overlaying a Scatter and a HighLow (Type=Bar). Make the high and low the same value to get a single line. You can set the BarWidth to control the width of the line.

Re: Now to create scatter plot like this?

PGStats — Wed, 15 Mar 2017 16:36:51 GMT

OK, one more try, following @Jay54's suggestion (tested with 9.4) :

proc sql;
create table class as
select *, median(weight) as med
from sashelp.class
group by age;
quit;

proc sgplot data=class noautolegend;
highlow x=age high=med low=med / type=bar lineattrs=(thickness=2 color=red) barwidth=0.6;
scatter y=weight x=age / markerattrs=(symbol=circlefilled color=blue);
xaxis type=discrete;
run;

Re: Now to create scatter plot like this?

JohnChen_TW — Thu, 16 Mar 2017 02:59:51 GMT

I'm creating the figure by your suggestion. Great thanks for everyone's suggestion!
Besides, the function "median" seems not okay in SAS 9.3. There will be a warning message "The MEDIAN function has been called with only one argument.".
However, 'mean' function can be worked in proc sql statement and that what I need!

Thanks again!

JC