topic Re: Re-asking question from 2015: How do I get tooltips to display for other users on saved images? in Graphics Programming

Re-asking question from 2015: How do I get tooltips to display for other users on saved images?

Dave25 — Wed, 08 Mar 2017 22:35:34 GMT

on a previous post, BrianMc asked about creating a file to share with others, that would include tips

ODS LISTING CLOSE;

ODS HTML PATH='c:\_Stuff' (URL=NONE)

BODY='BUBBLE.HTML'

STYLE=ANALYSIS;

ODS GRAPHICS / reset=all imagemap=on border=off antialiasmax=1800 tipmax=1800;

GOPTIONS NODISPLAY;

GOPTIONS XPIXELS=1200 YPIXELS=800;

ODS LISTING CLOSE;

ODS HTML PATH='c:\_Stuff' (URL=NONE)

BODY='BUBBLE.HTML'

STYLE=ANALYSIS;

ODS GRAPHICS / reset=all imagemap=on border=off antialiasmax=1800 tipmax=1800;

GOPTIONS NODISPLAY;

GOPTIONS XPIXELS=1200 YPIXELS=800;

RobertAllison responded that:

You can't just save the image - you must have both the image and the html (and view them in a Web browser) to see the tooltips.

So, my question - is there a way to do this? (save and share both?)

Thanks,

Dave

Re: Re-asking question from 2015: How do I get tooltips to display for other users on saved images?

Reeza — Wed, 08 Mar 2017 22:55:00 GMT

I don't think so, this is a limitation of the formats that are exported.

ie PNG don't support tooltips, pretty much only HTML does.

Re: Re-asking question from 2015: How do I get tooltips to display for other users on saved images?

Cynthia_sas — Wed, 08 Mar 2017 23:02:55 GMT

Hi: you have a mix of ODS GRAPHICS statements and GOPTIONS statements, but do not show your GRAPH code. The challenge with answering your question is that it really will depend on your SAS code. The option you use for tooltips with the SG Procedures is different from the options you use with SAS/GRAPH procedures.

And, if you want to insert accessible information into ODS output, you can use the accessible option on your GOPTIONS statement when you are using SAS/GRAPH.

So what is the rest of the code you are using for this ODS HTML file?

cynthia

Re: Re-asking question from 2015: How do I get tooltips to display for other users on saved images?

Dave25 — Wed, 08 Mar 2017 23:33:11 GMT

I've tried a number of different ways of doing the ods html statement, but here's one (it does create the htm file, which has the tips when I open it, but not when I send it)

Thanks!

Pared down data and code:

data test;
input PCT_PROF PCT_FR_LUNCH;
Tips = 'PCT PROF: '|| strip(put(PCT_PROF, percent10.))|| ' / PCT FR Lunch: '|| strip(put( PCT_FR_LUNCH, percent10.));
cards;
.5 .4
.7 .5
.9 .6
;
run;
ods graphics / reset;

ods html file='C:\a\sgplot.htm' body='plot.htm' ;
ods graphics / imagemap=on height=7in width=9in;

proc sgplot data=test;
Scatter y = PCT_PROF x = PCT_FR_LUNCH /markerattrs=(symbol=circlefilled color=blue size = 😎 tip=(tips);
run;

ods html close;

Re: Re-asking question from 2015: How do I get tooltips to display for other users on saved images?

Cynthia_sas — Thu, 09 Mar 2017 15:19:33 GMT

Hi, why do you have both a FILE= and a BODY=. I would expect to see PATH= and either FILE= or BODY=, but not both. Are you sure your files are being created correctly?

cynthia

Re: Re-asking question from 2015: How do I get tooltips to display for other users on saved images?

DanH_sas — Thu, 09 Mar 2017 15:19:55 GMT

If you are using SAS 9.4, you can get the HTML5 desitnation to embed the image into the HTML file, as well as the image map. It's a great way to send rich HTML content to someone via e-mail.

data test;
input PCT_PROF PCT_FR_LUNCH;
Tips = 'PCT PROF: '|| strip(put(PCT_PROF, percent10.))|| ' / PCT FR Lunch: '|| strip(put( PCT_FR_LUNCH, percent10.));
cards;
.5 .4
.7 .5
.9 .6
;
run;
ods graphics / reset;
ods html5 path="." (url=none) file="test.html" options(bitmap_mode="inline");
ods graphics / imagemap=on height=7in width=9in imagefmt=png;

proc sgplot data=test;
Scatter y = PCT_PROF x = PCT_FR_LUNCH /markerattrs=(symbol=circlefilled color=blue size = 8) tip=(tips);
run;
ods html5 close;

Hope this helps!

Dan

Re: Re-asking question from 2015: How do I get tooltips to display for other users on saved images?

Dave25 — Thu, 09 Mar 2017 17:20:19 GMT

exactly what I was hoping to get -- thank you!!