topic Re: Outputting KM curve with transparent background in Graphics Programming

Outputting KM curve with transparent background

MiraKr_ — Mon, 06 Mar 2017 20:09:22 GMT

Dear all,

I am trying to ouput a KM curve using proc lifetest, but with with transparent background. This way, I can overlay the image over another JPEG image and see if the curves overlap. At the moment, the JPEG image appears with white, non-transparent background. I wish to keep everything the same (curve colors, etc) except the the background.

ods rtf file="&outputloc\test.rtf";
proc lifetest data=test method=KM
plots=survival(atrisk=0 to 30 by 3) timelist=0 to 30 by 3;
time os_m*censors(0);
strata treat;
title1 'Kaplan-Meier Plot for OS';
label os_m="Months";
where itt=1;
run;
ods rtf close;

Thank you,

Re: Outputting KM curve with transparent background

MiraKr_ — Mon, 06 Mar 2017 20:12:59 GMT

PS: These need to go in a power point slide deck.

Re: Outputting KM curve with transparent background

Reeza — Mon, 06 Mar 2017 20:33:38 GMT

I'm assuming you're not using SAS 9.4 since you're not using ODS PPT?

Anyways, here's a starter on customizing survival plots. It's not as easy as you'd like, unfortunately.

http://support.sas.com/documentation/cdl/en/statug/68162/HTML/default/viewer.htm#statug_kaplan_toc.htm

Re: Outputting KM curve with transparent background

Jay54 — Mon, 06 Mar 2017 20:52:11 GMT

With SAS 9.40M3, GTL supports output with transparent background. You will also have to make the wall transparent.

See OPAQUE option in BEGINGRAPH.

Re: Outputting KM curve with transparent background

MiraKr_ — Tue, 07 Mar 2017 04:00:51 GMT

I am using SAS 9.4. Do you have a sample code that outputs the KM graph with transparent background?

Re: Outputting KM curve with transparent background

Jay54 — Tue, 07 Mar 2017 14:05:32 GMT

If you have SAS 9.40M3 (M3 is important), you can do one of the following:

Change the PROC Lifetest template.

Find the name of the template using ODS TRACE on;
Then update the template to make the background and wall transparent.
Rerun your proc lifetest program.

Or, run the lifetest procedure and get the data saved to a sas data set using ODS OUTPUT.

Run your own SGPLOT program to create the Survival plot using program below.
Note the NOOPAQUE and NOWALL options on the SGPLOT procedure statement.

/*--Get survival plot data from LIFETEST procedure--*/
ods graphics on;
ods output Survivalplot=SurvivalPlotData;
proc lifetest data=sashelp.BMT plots=survival(atrisk=0 to 2500 by 500);
time T * Status(0);
strata Group / test=logrank adjust=sidak;
run;

/*--Survival Plot with outer Risk Table using AxisTable Transparent--*/
ods html close;
ods graphics / reset imagename='Survival Plot_SG_V94_Trans';
title 'Product-Limit Survival Estimates';
title2 h=0.8 'With Number of AML Subjects at Risk';
proc sgplot data=SurvivalPlotData noopaque nowall;
step x=time y=survival / group=stratum lineattrs=(pattern=solid) name='s';
scatter x=time y=censored / markerattrs=(symbol=plus) name='c';
scatter x=time y=censored / markerattrs=(symbol=plus) GROUP=stratum;
xaxistable atrisk / x=tatrisk location=outside class=stratum colorgroup=stratum;
keylegend 'c' / location=inside position=topright;
keylegend 's';
run;

Re: Outputting KM curve with transparent background

MiraKr_ — Tue, 07 Mar 2017 14:24:16 GMT

Thank you Sanjay_SAS! I tried running this code, but I guess I do not have M3 because I got an error message that the "noopaque" option is unrecognized. Is M3 something that can be dowloaded or do I have to purchase it separately?

Many thanks,

Mira

Re: Outputting KM curve with transparent background

Jay54 — Tue, 07 Mar 2017 15:28:03 GMT

I believe you (or your company) can upgrade to a new maintenance release.

Contact contracts@sas.com, or, call our customer service line 919-677-8003.