topic Re: Histogram with frequency count in Graphics Programming

Histogram with frequency count

deega — Wed, 30 Nov 2016 05:07:48 GMT

Hi I am using below codes to make a histogram

proc univariate data=filename noprint;
histogram VAR1 ;
run;

I am getting histogram in the output but with Percentage and I want with Frequency count. Could anybody please help me on the same.

Re: Histogram with frequency count

Reeza — Wed, 30 Nov 2016 05:33:44 GMT

I'm not seeing an option in PROC UNIVARIATE, but SGPLOT HISTOGRAM statement has a SCALE=Count option.

Proc SGPLOT data=SASHELP.class;

hisotgram age / scale = count;

run;

Re: Histogram with frequency count

Rick_SAS — Wed, 30 Nov 2016 10:28:14 GMT

The documentation for the HISTOGRAM statement in PROC UNIVARIATE shows that you can use

VSCALE=COUNT

Other options are VSCALE=PERCENT (the default) and VSCALE=PROPORTION.

Re: Histogram with frequency count

arcacha — Tue, 21 Sep 2021 20:05:29 GMT

In regards to the frequency count variable, is there anyway to format that variable? (eg comma format?)

Re: Histogram with frequency count

Rick_SAS — Tue, 21 Sep 2021 20:45:51 GMT

That's an interesting question. I think for large samples, most people switch to PERCENT as a scale instead of COUNT.

I suppose you could write the binned counts to a data set and then use a vertical bar chart:

data Have;
do i = 1 to 1e6;
   x = rand("Normal", 10, 2);
   output;
end;
run;

Proc univariate data=Have noprint;
var x;
histogram x / VSCALE=COUNT outhist=Want;
run;

proc sgplot data=Want;
format _COUNT_ comma7.;   /* apply COMMA format */
vbarbasic _MIDPT_ / response=_COUNT_;
xaxis type=linear values=(0 to 20 by 2);
run;

Re: Histogram with frequency count

arcacha — Wed, 22 Sep 2021 14:26:07 GMT

That's perfect - exactly what I was look for! Pity PROC UNIVARIATE doesn't have the same functionality.

Thanks again!