topic Find the last day of the month in SAS Enterprise Guide

Find the last day of the month

Droopy — Thu, 20 Aug 2009 11:58:03 GMT

I want to find, in entreprise guide, the last day of the month. I only have a string who represent the month and the year (e.q : "200908") I want to compute a real date ==> "08/31/2009". Is anyone can help me.

Best regards.

Re: Find the last day of the month

FredrikE — Thu, 20 Aug 2009 12:04:14 GMT

try this sample program:

data _null_;
a = '200901';
b = intnx('month',input(a,yymmn6.),0,'end');
put b yymmdd10.;
run;

In EG use the expression (intnx('month',input(a,yymmn6.),0,'end')) to create a new variable.

//Fredrik

Re: Find the last day of the month

DF — Thu, 20 Aug 2009 12:09:05 GMT

Hi Droopy,

To do this, I would convert your text string to a normal date, then make use of the INTNX function to go forward a month, then back a day.

For example, 200908 would be converted to 08/01/2009 (sticking with US style dates). Jump forward a month to 09/01/2009, then go back a day to 08/31/2009.

The below code create a sample dataset with months stored as text, and then does the above calculation.

data months;
format month $10.;
input month $;
datalines;
200002
200908
200402
;
run;

data months;
set months;
format last_day date9.;
last_day = intnx('day',intnx('month',input(month,yymmn6.),1),-1);
run;

The Input function converts the text date to its numerical equivalent, then intnx is used as above.

Hope that helps.

Re: Find the last day of the month

DF — Thu, 20 Aug 2009 12:11:10 GMT

Oops - double response. That's what I get for being slow, lol.

Re: Find the last day of the month

Droopy — Thu, 20 Aug 2009 12:41:32 GMT

Thanks all. It's work !!! 😉