topic How to format a global variable in SAS Enterprise Guide

How to format a global variable

deleted_user — Wed, 20 Aug 2008 12:25:14 GMT

I define a global variable as follows:
%let todaydate=today();
and SAS assign a number to the 'todaydate'. Anyone knows whether it is possible for me to format the 'todaydate', e.g. ddmmyy or ddmonyy etc?

Re: How to format a global variable

LinusH — Wed, 20 Aug 2008 12:31:36 GMT

Try

%let todaydate = %sysfunc(putn("&SYSDATE9"D,ddmmyy.));

Regards,
Linus

Re: How to format a global variable

Cynthia_sas — Wed, 20 Aug 2008 12:46:56 GMT

Hi:
If you DO want to use the today() function instead of &SYSDATE9, you can use it directly in the %LET, and with the TODAY() function, a second argument is allowed for %SYSFUNC that formats the returned date:
[pre]
%let d1 = %sysfunc(today(),ddmmyy.);
%let d2 = %sysfunc(today(),worddate.);
%let d3 = %sysfunc(today(),mmddyy10.);
%let d4 = %sysfunc(putn("&sysdate9"d ,mmddyyp10.));
%let d5 = %sysfunc(putn('01Jan2008'd ,weekdate.));

%put d1= &d1;
%put d2= &d2;
%put d3= &d3;
%put d4= &d4;
%put d5= &d5;
[/pre]

cynthia

Re: How to format a global variable

deleted_user — Wed, 20 Aug 2008 12:49:10 GMT

Hihi,

just tried but sas still assign some other number to the date..

Re: How to format a global variable

Cynthia_sas — Wed, 20 Aug 2008 16:42:59 GMT

Hi:
&SYSDATE may not be the same date as TODAY(). Especially if your version of SAS is on a server that is not taken down often. Usually &SYSDATE is the date that the SAS session started...while TODAY() returns a value from the computer's "calendar/clock" functions.

Are you saying that today() does not return today's date????

[pre]
%let x = %sysfunc(today());
%let y = %sysfunc(today(),mmddyy10.);
[/pre]

If these statements do not produce the following results, then you should contact Tech Support for more help. (If you're on the other side of the international date line, of course, your date will be off from mine by a day.
[pre]
1 %let x = %sysfunc(today());
2 %let y = %sysfunc(today(),mmddyy10.);
3
4 %put *******x=&x y=&y;
*******x=17764 y=08/20/2008

[/pre]

Today's date in as a SAS number is 17764. With the mmddyy10. format applied, the macro variable &Y has a value of 08/20/2008.

cynthia

Re: How to format a global variable

deleted_user — Thu, 21 Aug 2008 11:02:31 GMT

Hi..

I manage to get it already! Thanks so much for everybody's help.
\(^o^)/