topic Re: do while is not working in SAS Enterprise Guide

do while is not working

alepage — Wed, 20 Aug 2025 21:23:41 GMT

the do while is not working.

What's wrong ?

data paths;
     length path $200;
     input path $;
     datalines;
/dwh_actuariat/sasprocess/prodmens/HYFIprep/output
/dwh_actuariat/sasprocess/prodmens/HYFIp/output
;
run;
%macro process;
proc sql noprint;
     select path into :path_list separated by ' '
     from paths;
quit;

%put &=path_list;


%let i = 1;
%do %while (%scan(&path_list, &i. , ' ') ne '');
     %let current_path = %scan(&path_list, &i. , ' ');
     %put &=current_path;
     %let i = %eval(&i. + 1);
%end;


%mend process;
%process;

Re: do while is not working

Ksharp — Thu, 21 Aug 2025 01:17:24 GMT

data paths;
     length path $200;
     input path $;
     datalines;
/dwh_actuariat/sasprocess/prodmens/HYFIprep/output
/dwh_actuariat/sasprocess/prodmens/HYFIp/output
;
run;
%macro process;
proc sql noprint;
     select path into :path_list separated by ' '
     from paths;
quit;

%put &=path_list;


%let i = 1;
%do %while (%qscan(&path_list, &i. ,%str( )) ne );
     %let current_path = %scan(&path_list, &i. , %str( ));
     %put &=current_path;
     %let i = %eval(&i. + 1);
%end;


%mend process;
%process;

Re: do while is not working

Tom — Thu, 21 Aug 2025 16:33:14 GMT

Why did you tell SQL to use space as the delimiter and tell %SCAN() to also include single quote as a delimiter? And why did you compare the value to something that does contain single quote characters? That will never match as the result of the %SCAN() function could never contain any single quotes since they are being used as delimiters.

Note since you want to use %SCAN() to split the macro variable it will work better to use some character that cannot appear in a path as the delimiter, such as a | character.

Also SAS will not like those / characters in the strings generated by the %SCAN() call.

PATH_LIST=/dwh_actuariat/sasprocess/prodmens/HYFIprep/output /dwh_actuariat/sasprocess/prodmens/HYFIp/output
ERROR: A character operand was found in the %EVAL function or %IF condition where a numeric operand is required. The condition was:
       %scan(&path_list, &i. ,  ) ne
ERROR: The condition in the %DO %WHILE loop, %scan(&path_list, &i. ,  ) ne, yielded an invalid or missing value, .  The macro
       will stop executing.
ERROR: The macro PROCESS will stop executing.

If you want to get your complex looping code to work make sure to use the right delimiter and compare to and actual empty value and use macro quoting to protect the value of the path from confusing the %EVAL() used by the %WHILE().

%do %while (%qscan(&path_list, &i. , %str( )) ne );

But why would you use such a complex loop when you can just use a NORMAL iterative do loop?

%macro process;
%local path_list i n current_path;
proc sql noprint;
  select path into :path_list separated by '|'
  from paths;
quit;
%let n=&sqlobs;

%do i=1 %to &n;
  %let current_path = %scan(&path_list, &i. ,|);
  %put &=i &=current_path;
%end;
%mend process;

Results

I=1 CURRENT_PATH=/dwh_actuariat/sasprocess/prodmens/HYFIprep/output
I=2 CURRENT_PATH=/dwh_actuariat/sasprocess/prodmens/HYFIp/output

And if you want to loop over a delimited list where you don't know the number of items in advance just count them.

%do i=1 %to %sysfunc(countw(&path_list,|));
  %let current_path = %scan(&path_list, &i. ,|);
  %put &=i &=current_path;
%end;

Re: do while is not working

andreas_lds — Thu, 21 Aug 2025 06:12:34 GMT

From my point of view the first error is moving data from a dataset into macro variables, which is not necessary in most cases.

Re: do while is not working

yabwon — Thu, 21 Aug 2025 07:25:53 GMT

How about using macroArray packge and create a macro variable array?

1) Documentation.

2) Article describing the package.

Example:

/* load package to your SAS session */
%loadPackage(macroArray)


/* data */
data paths;
     length path $200;
     input path $;
     datalines;
/dwh_actuariat/sasprocess/prodmens/HYFIprep/output
/dwh_actuariat/sasprocess/prodmens/HYFIp/output
;
run;


/* create m.v.a. Path */
%array(ds=paths,vars=path,macarray=Y)

/*
optionally preview:
%put %do_over(path);
*/

/* use macro variable array  */
%macro test(i);

%do i = 1 %to &i.;
  %put &=i. #%path(&i.)#; /* call %path() macro to get values one by one */
%end;

%mend;

%test(&pathN.) /* pathN macro variable keep size */

/* clean up */
%deleteMacArray(path,macarray=Y)

Log:

1
2
3    data paths;
4         length path $200;
5         input path $;
6         datalines;

NOTE: The data set WORK.PATHS has 2 observations and 1 variables.
NOTE: DATA statement used (Total process time):
      real time           0.00 seconds
      user cpu time       0.00 seconds
      system cpu time     0.00 seconds
      memory              404.96k
      OS Memory           25908.00k
      Timestamp           08/21/2025 09:24:43 AM
      Step Count                        289  Switch Count  0


9    ;
10   run;
11
12
13   /* create */
14   %array(ds=paths,vars=path,macarray=Y)
NOTE:[ARRAY] 2 macrovariables created
15
16   /*
17   optionally preview:
18   %put %do_over(path);
19   */
20
21   /* use macro variable array  */
22   %macro test(i);
23
24   %do i = 1 %to &i.;
25     %put &=i. #%path(&i.)#;
26   %end;
27
28   %mend;
29
30   %test(&pathN.)
I=1 #/dwh_actuariat/sasprocess/prodmens/HYFIprep/output#
I=2 #/dwh_actuariat/sasprocess/prodmens/HYFIp/output#
31
32   /* clean up */
33   %deleteMacArray(path,macarray=Y)

Bart

P.S. How to install MacroArray package?

1) Create a directory of your convenience, for example:

C:\users\myuser\Desktop\Packages

2) In your SAS session, run the following line of code:

filename packages "C:\users\myuser\Desktop\Packages";

For Linux change the path accordingly

3) To install the SAS Packages Framework, execute the code (only one time):

/* enable a temporary version of the framework */
filename SPFinit url 
 "https://raw.githubusercontent.com/yabwon/SAS_PACKAGES/main/SPF/SPFinit.sas";      
%include SPFinit; 

/* install the framework */
%installPackage(SPFinit)

filename SPFinit clear;

4) To install the package macroArray run the following code:

%installPackage(macroArray)

5) In order to use the SPF and packages in a SAS session, they must be enabled and loaded first. This is very straightforward, all we need to do is to assign the packages filename to the packages directory, then include the framework code, and load a package we need. To do so execute 3 lines of code:

filename packages "/path/to/my/packages";
%include packages(SPFinit.sas);
%loadPackage(macroArray)

See SAS packages tutorial for more details.

Re: do while is not working

Kurt_Bremser — Thu, 21 Aug 2025 08:41:56 GMT

In its current form, the macro does nothing but write values to the log, which can easily be achieved in a single DATA step without any macro language.

What is your real task?

Re: do while is not working

Ksharp — Thu, 21 Aug 2025 09:30:16 GMT

Kurt,
I just copy the code from OP and fixed it.
I have no idea about what is OP's intention.

Re: do while is not working

PaigeMiller — Thu, 21 Aug 2025 09:54:42 GMT

Agreeing with @Kurt_Bremser , there is no point in using macros for this task. So @alepage what is the real problem you are trying to solve?

Re: do while is not working

Kurt_Bremser — Thu, 21 Aug 2025 11:34:32 GMT

Oh, sorry, that should have been a reply to @alepage's original post.

Re: do while is not working

alepage — Thu, 21 Aug 2025 17:49:10 GMT

Well I want to use the macro process to passed as parameter the two different paths. Then I will replace the %put statement by another macro function that is loading all the txt files into that folder into a sas dataset.

Re: do while is not working

alepage — Thu, 21 Aug 2025 17:56:57 GMT

I will replace the %put by another macro function.

Re: do while is not working

alepage — Thu, 21 Aug 2025 17:58:34 GMT

Why did you replace the %scan by %pscan and the '' by %str() and ne )

Please explain.
Your script work perfectly

Re: do while is not working

Tom — Thu, 21 Aug 2025 18:27:25 GMT

@alepage wrote:
Why did you replace the %scan by %pscan and the '' by %str() and ne )

Please explain.
Your script work perfectly

%QSCAN() adds macro quoting to the path so that %EVAL() does not see the / as division symbols.

You do not need to enclose strings in quotes for the macro processor. The reason you need the quotes in SAS code is so SAS knows what to treat as strings and what to treat as variable names or keywords. But to the macro processor everything is a string. So the quotes become part of the string.

Re: do while is not working

Tom — Thu, 21 Aug 2025 18:30:46 GMT

@alepage wrote:

Well I want to use the macro process to passed as parameter the two different paths. Then I will replace the %put statement by another macro function that is loading all the txt files into that folder into a sas dataset.

So skip the macro and the macro variables and just use a data step to generate the calls to the macro.

So if your macro is named %MYMACRO() and takes the path as the first positional argument you could generate one call to the macro for each observation in the data PATHS with this data step:

data _null_;
  set paths;
  call execute(cats('%nrstr(%mymacro)(',path,')'));
run;

Re: do while is not working

alepage — Thu, 21 Aug 2025 18:39:58 GMT

for Mr. Miller here's my complete script

data paths;
     length path $200;
     input path $;
     datalines;
/dwh_actuariat/sasprocess/prodmens/HYFIprep/output
/dwh_actuariat/sasprocess/prodmens/HYFIp/output
;
run;

/************************************************************/

%macro readfile(path,fname,suffix);
    DATA &fname.;
        INFILE "&path./&fname..&suffix";
        INPUT Cie $ 1
              province $ 2-3
              branch   $ 4-7
              priorcur $ 8
               polsrc  $ 9
               mois    $ 10-15
               lob     $ 16-23
               Trans   $ 24-26
               WP       27-41
               EP       42-56
               EU       57-71
               WU       72-86
               POLCNT   87-102
               POLEARN  103-117
               UW_CIE   $ 118
               DIST_CIE  $ 119
               OB_IND    $ 120-124
               BROKER_GROUP_IND $ 125-126
               GCNA_BRANCH      $ 127-128               
               POLICY_CATEGORY  $ 129
               NETWORK_PROVIDER $ 130-134
               AFFINITY_IND     $ 135
;
    RUN;
%mend readfile;
/*******************************************************/
%macro readtxtfile;
%let yearmin=2024;
%let yearmax=2025;
%let prefix=HyFIPrems;
%let suffix=txt;
%let path=/dwh_actuariat/sasprocess/prodmens/HYFIprep/output;

%do year = &yearmin %to &yearmax;
     %if &year. ne &yearmax. %then %let maxmonth=12; 
     %else %let maxmonth=7;
     %do month =01 %to &maxmonth.;
     %let formatted_month = %sysfunc(putn(&month, Z2.));
     %let fname=&prefix.&year.&formatted_month.;
          %put &fname..&suffix.;
          %readfile(&path,&fname,&suffix);

          PROC APPEND BASE=&prefix. DATA=&fname.;
          RUN;
     %end;
%end;

%mend readtxtfile;
/******************************************/
*%readtxtfile;

%macro readtxtfile2(path);
%let yearmin=2025;
%let yearmax=2025;
%let minmonth=1;
%let maxmonth=7;

%let prefix=HyFIPrems;
%let suffix=txt;


%do year = &yearmin %to &yearmax;     
     %do month =&minmonth. %to &maxmonth.;
     %let formatted_month = %sysfunc(putn(&month, Z2.));
     %let fname=&prefix.&year.&formatted_month.;
          %put &fname..&suffix.;
          
          %readfile(&path,&fname,&suffix);

          %let substring=prep;


          %if %sysfunc(find(&path. , &substring.)) > 0 %then 
          %do;
               PROC APPEND BASE=&prefix. DATA=&fname.;
               RUN;
          %end;
          %else
          %do;
               PROC APPEND BASE=&prefix._org DATA=&fname.;
               RUN;
          %end; 


          
     %end;
%end;

%mend readtxtfile2;
%macro process;
proc sql noprint;
     select path into :path_list separated by ' '
     from paths;
quit;

%put &=path_list;


%let i = 1;
%do %while (%qscan(&path_list, &i. ,%str( )) ne );
     %let current_path = %scan(&path_list, &i. , %str( ));
     %put &=current_path;
     %readtxtfile2(&current_path);

     %let i = %eval(&i. + 1);
%end;


%mend process;
%process;

Re: do while is not working

Tom — Thu, 21 Aug 2025 19:30:31 GMT

Macro programming is fun, but don't use it when it is not needed.

Looks to me like you want to run this data step to create your two output datasets.

data paths;
  infile datalines truncover;
  input path $200.;
datalines;
/dwh_actuariat/sasprocess/prodmens/HYFIprep/output
/dwh_actuariat/sasprocess/prodmens/HYFIp/output
;

%let prefix=HyFIPrems;
%let substring=prep;

data &prefix. &prefix._org ;
  set paths;
  do year=2025 to 2025 ;
    do month = 1 to 7 ;
      length fname $256 ;
      fname=catx('/',path,cats("&prefix",year,put(month,z2.),'.txt'));
      infile text filevar=fname truncover end=eof; 
      do while(not eof);
        INPUT Cie $ 1
              province $ 2-3
              branch   $ 4-7
              priorcur $ 8
              polsrc  $ 9
              mois    $ 10-15
              lob     $ 16-23
              Trans   $ 24-26
              WP       27-41
              EP       42-56
              EU       57-71
              WU       72-86
              POLCNT   87-102
              POLEARN  103-117
              UW_CIE   $ 118
              DIST_CIE  $ 119
              OB_IND    $ 120-124
              BROKER_GROUP_IND $ 125-126
              GCNA_BRANCH      $ 127-128               
              POLICY_CATEGORY  $ 129
              NETWORK_PROVIDER $ 130-134
              AFFINITY_IND     $ 135
        ;
        if find(path,"&substring") then output  &prefix.;
        else output &prefix._org ;
      end;
    end;
  end;
run;

Re: do while is not working

Ksharp — Fri, 22 Aug 2025 01:23:40 GMT

1)Actually, @Tom has already answered your question.
The secret hided in operator "NE".
When sas meet "NE" ,would put %eval() around "/dwh_actuariat/sasprocess/prodmens/HYFIp/output"
and since "/" is a divided operator in sas ,sas would take it as a divided operator, and lead to this error.
Here I use %QSCAN() is to mask "/" operator to avoid this error as Tom show you detailly .

2)A white blank is a special character in MACRO language, so I use %str( ) to mask it to let MACRO know it as I use %qscan() to mask "/“ divided operator.

3)As @Tom pointed out MACRO take everything as a STRING , you don't need to put quote around it just leave it as a blank . Otherwise, MACRO would take it as "a blank", not a NULL character(empty).

Re: do while is not working

alepage — Fri, 22 Aug 2025 13:37:38 GMT

Yes you are right, that will do the same