topic convert date to datime in SAS Enterprise Guide

convert date to datime

alepage — Fri, 28 Jun 2024 12:59:45 GMT

data test2;
PIT_day = intnx('day',(intnx('month',date(),-1,'e')),-2);
AUTH_DT = intnx('dtday',(intnx('dtmonth',datetime(),-0, 'b')),-3) +'20:00:00't ;
AUTH_DT2 = PIT_day +'20:00:00't ;
format pit_day date9. AUTH_DT2 auth_dt datetime19.;
run;

The PIT_day and AUTH_DT gives the expected values.

However, if I want to reuse the value of PIT_day like in AUTH_DT2, it does not give 29MAY2024:20:00:00

How could we do that ?

Re: convert date to datime

Kurt_Bremser — Fri, 28 Jun 2024 13:05:01 GMT

This cannot work:

AUTH_DT2 = PIT_day +'20:00:00't ;

SAS dates are counts of days, while times are counts of seconds; you are mixing apples and oranges here.

Use the DHMS function instead:

auth_dt2 = dhms(pit_day,20,0,0);

Re: convert date to datime

Tom — Fri, 28 Jun 2024 13:05:18 GMT

If you want to convert a DATE value (number of days) into a DATETIME value (number of seconds) you could just multiply the value by the number of seconds in a day ('24:00:00't).

datetime = date*'24:00:00't ;

But SAS also has a function that does that. DHMS(days,hours,minutes,seconds).

datetime = dhms(date,0,0,0);

You could also just create a datetime value to begin with.

PIT_dt = intnx('dtday',(intnx('dtmonth',datetime(),-1,'e')),-2);
format pit_dt datetime19.;