topic Re: Call python with parameters for each row of SAS dataset in SAS Enterprise Guide

Call python with parameters for each row of SAS dataset

MM88 — Wed, 26 Jul 2023 14:25:27 GMT

Hi community,

I would like to call a python program for each row of my dataset. My dataset has 4 variables, that I need to pass as parameters to the python call.

data _null_;
  set mydataset;
  command = 'python C:\temp\mypython.py ' || " " || quote(strip(var1)) || " " || quote(var2) || " " || quote(var3) || " " || quote(var4);
  X command;
run;

But no python call is executed.

Any suggestions of what could be the problem?

Thanks

Re: Call python with parameters for each row of SAS dataset

Tom — Wed, 26 Jul 2023 15:19:57 GMT

That is not how the X (aka SYSTEM) command works.

You could do it with a pipe instead.

data _null_;
  set mydataset;
  length command $200;
  command = catx(' ','python C:\temp\mypython.py',quote(trim(var1)),quote(trim(var2)),quote(trim(var3)),quote(trim(var4)));
  infile cmd pipe filevar=command end=eof;
  do while not(eof);
    input;
    put _infile_;
  end;
run;

Re: Call python with parameters for each row of SAS dataset

MM88 — Thu, 27 Jul 2023 09:49:48 GMT

Thanks @Tom, it works your solution. Only in my system expects parenthesis in:
do while (not(eof));
Regards

Re: Call python with parameters for each row of SAS dataset

Ksharp — Thu, 27 Jul 2023 11:54:01 GMT

/*
You could make a BAT file and execute it by X command.
*/
filename x 'c:\temp\run.bat';   /*<--Here is a BAT file to run SHELL command*/
data _null_;
  set mydataset;
  command = 'python C:\temp\mypython.py ' || " " || quote(strip(var1)) || " " || quote(var2) || " " || quote(var3) || " " || quote(var4);
file x;
put command ;
run;

options noxwait;
X 'c:\temp\run.bat';  /*<--Here is a BAT file to run SHELL command*/